Die Community zu .NET und Classic VB.
Menü

VB.NET-Tipp 0002: Die Verwendung der ArrayList-Klasse

 von 

Beschreibung

Dieses Beispiel zeigt den einfachen Umgang mit Arraylisten, nämlich Hinzufügen und Durchlaufen der Liste über eine For...Each-Schleife sowie den Elementindex. Ausserdem wird eine Arrayliste auf Basis einer bestehenden Collection erstellt.

Zu diesem Tipp existieren im Tippupload die folgende(n) Aktualisierung(en):
[VB .NET Tippvorschlag 0036] Arrays, Listen, Dictionaries - Initialisierung + Mehrdimensionalität

Schwierigkeitsgrad:

Schwierigkeitsgrad 1

Framework-Version(en):

.NET Framework 1.0, .NET Framework 1.1, .NET Framework 2.0, .NET Framework 3.0, .NET Framework 3.5

.NET-Version(en):

Visual Basic 2002, Visual Basic 2003, Visual Basic 2005, Visual Basic 2008

Download:

Download des Beispielprojektes [2,14 KB]

' Dieser Quellcode stammt von http://www.activevb.de
' und kann frei verwendet werden. Für eventuelle Schäden
' wird nicht gehaftet.

' Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
' Ansonsten viel Spaß und Erfolg mit diesem Source!

' Projektversion:   Visual Studio 2002/2003
' Option Strict:    An
' Option Explicit:  An
'
' Referenzen: 
'  - System
'

' ##############################################################################
' ################################## Main.vb ###################################
' ##############################################################################
Option Explicit On 
Option Strict On
Option Compare Binary

Imports Microsoft.VisualBasic
Imports System
Imports System.Collections

' <remarks>
'   Stellt den Einsprungspunkt der Anwendung bereit.
' </remarks>
Public Class Main

    ' <summary>
    '   Der Einsprungspunkt der Anwendung.
    ' </summary>
    Public Shared Sub Main()

        ' Erstellen einer Collection und 
        ' Hinzufügen von Werten.
        Dim col As Collection = New Collection()
        col.Add("Ich wurde der Collection hinzugefügt.")

        ' Erstellen einer Arrayliste, die als Adapter 
        ' für die Collection dient.
        Dim al As ArrayList = ArrayList.Adapter(col)
        al.Add("Ich wurde der Arrayliste hinzugefügt.")
        al.Add(23)
        al.Add(22.9923)
        al.Add(New User("Clim Binton", Convert.ToUInt32(62)))

        ' Durchlaufen über eine For...Each-Schleife.
        Console.WriteLine("Durchlaufen über For...Each:")
        Dim objElement As Object
        For Each objElement In al
            Console.WriteLine("  ""{0}""", _
              objElement.ToString())
        Next objElement

        ' Durchlaufen über den Index der Elemente.
        Console.WriteLine("Durchlaufen über den Index:")
        Dim i As Integer
        For i = 0 To al.Count - 1
            Console.WriteLine("  ""{0}""", al.Item(i))
        Next i
    End Sub
End Class
' ##############################################################################
' ################################## User.vb ###################################
' ##############################################################################
Option Explicit On 
Option Strict On
Option Compare Binary

Imports System

' <remarks>
'   Stellt einen Benutzer dar.
' </remarks>
Public Class User
    Private m_strName As String
    Private m_uintAge As UInt32

    ' <summary>
    '   Erstellt eine Instanz der Klasse auf 
    '   und weist den Eigenschaften die in
    '    den Parametern übergebenen Werte zu.
    ' </summary>
    ' <param name="strName">Name des Benutzers.</param>
    ' <param name="uintAge">Alter des Benutzers.</param>
    Public Sub New(ByRef strName As String, _
      ByVal uintAge As UInt32)
        Name = strName
        Age = uintAge
    End Sub

    ' <summary>
    '   Gibt den Namen des Benutzers an 
    '   oder gibt ihn zurück.
    ' </summary>
    ' <value>Name des Benutzers.</value>
    Public Property Name() As String
        Get
            Return m_strName
        End Get
        Set(ByVal Value As String)
            m_strName = Value
        End Set
    End Property

    ' <summary>
    '   Gibt das Alter des Benutzers 
    '   an oder gibt es zurück.
    ' </summary>
    ' <value>Alter des Benutzers.</value>
    Public Property Age() As UInt32
        Get
            Return m_uintAge
        End Get
        Set(ByVal Value As UInt32)
            m_uintAge = Value
        End Set
    End Property

    ' <summary>
    '   Erstellt einen String, der die 
    '   Instanz repräsentiert und gibt sie zurück.
    ' </summary>
    ' <returns>Gibt eine Textrepräsentation der 
    '   Instanz zurück.</returns>
    Public Overrides Function ToString() As String
        Return String.Concat(Name, ", ", Age)
    End Function
End Class

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Holger Scharfberger am 15.02.2011 um 13:10

Hallo Ihr netten Leute die sich die Mühe machen,
anderen Leuten das Programmieren zulehren.
Keine Kommentare,deuten auf Desinteresse oder zu faul zum
schreiben.
Ich selber bin schon ein alter Knochen,möchte es aber doch
noch wissen ,und habe mich entschlossen zu Programmieren.
Als Rentner habe ich genügend Zeit,um eventuell Spiele
zu entwickeln.Zuerst kommen aber die Grundlagen des Visual
Basic.Nun ich habe auf meinen Rechner VB2010.
Es soll sogar eine Spiele-Entwicklung für VB2008-2010 geben,
mit der man per Drag and Drop,Spiele entwickeln kann?
Möchte mich bedanken für Ihre sehr gutes Tutorial.
Herzliche Grüsse aus Hamburg
Holger Scharfberger