Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0733: Alle Sprachen auflisten

VB 5/6-Tipp 0733: Alle Sprachen auflisten

 von Oliver Meyer

Schwierigkeitsgrad:

Verwendete API-Aufrufe: VerLanguageNameA

Download: Download des Beispielprojektes [1,85 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Listen-Steuerelement "List1"
' Steuerelement: Schaltfläche "BtnListLCIDString"
Option Explicit
Private Declare Function VerLanguageNameA Lib "kernel32.dll" ( _
    ByVal wLang As Long, ByVal szLang As String, ByVal nSize As Long _
    ) As Long

Private Sub BtnListLCIDString_Click()
    Dim i As Long, j As Long
    Dim sBuf As String * 256
    Dim HashCol As New Collection
        Dim c As Long
    Dim sLen As Long
    Dim sLCItem As String
    Dim sH As String
    Dim sItem As String
    Dim lcid As Long
  
    For i = 0 To &HFF
        For j = 0 To &H10
            lcid = j * &H400 + i
            sLen = VerLanguageNameA(lcid, sBuf, 256)
            If sLen > 0 Then
                sLCItem = Left$(sBuf, sLen)
                If Not IsInList(HashCol, sLCItem) Then
                    sH = Hex$(lcid)
                    sH = String$(4 - Len(sH), "0") & sH
                    sItem = "&H" & sH & "   " & sLCItem
                    c = c + 1
                    sH = CStr(c)
                    sH = String$(3 - Len(sH), "0") & sH & "    "
                    sItem = sH & sItem
                    Call List1.AddItem(sItem)
                End If
            End If
        Next
    Next
End Sub

Private Function IsInList(aCol As Collection, strKey As String) As Boolean
  On Error Goto Err1
  
  Call aCol.Add(strKey, strKey)
  If Err.Number = 0 Then Exit Function
  
Err1:
  IsInList = True
End Function
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------