Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0682: Ein Formular zur Laufzeit in der Taskleiste ein- oder ausblenden

 von 

Beschreibung 

Die Eigenschaft ShowInTaskbar von Formularen kann normalerweise nur im Entwurfsmodus gesetzt werden, da diese Eigenschaft zur Laufzeit schreibgeschützt ist. Dieser Tipp zeigt Ihnen, wie Sie zur Laufzeit das Formular in der Taskleiste ein- oder ausblenden können.

Schwierigkeitsgrad:

Schwierigkeitsgrad 1

Verwendete API-Aufrufe:

GetWindowLongA (GetWindowLong), SetWindowLongA (SetWindowLong)

Download:

Download des Beispielprojektes [3,09 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'---------- Anfang Projektdatei ShowInTaskbar.vbp  ----------
'--- Anfang Formular "frmShowInTaskbarForm" alias frmShowInTaskbarForm.frm  ---
' Steuerelement: Kontrollkästchen-Steuerelement "ckShowInTaskbar"

Option Explicit

Private Sub ckShowInTaskbar_Click()
    ' Form in der Taskleiste ein- oder ausblenden
    Call ShowInTaskbarForm(Me, CBool(ckShowInTaskbar.Value * -1))
End Sub

Private Sub Form_Load()
    ' CheckBox Parameter setzen
    With ckShowInTaskbar
        .Move 60, 60, 3450, 255
        .Caption = "Form in der Taskleiste ein- oder ausblenden"
        .Value = 1
    End With
    
    ' Form anzeigen
    Me.Visible = True
End Sub
'--- Ende Formular "frmShowInTaskbarForm" alias frmShowInTaskbarForm.frm  ---
'--- Anfang Modul "modShowInTaskbarForm" alias modShowInTaskbarForm.bas ---

Option Explicit

' ----==== Konstanten ====----
Private Const GWL_EXSTYLE As Long = (-20)
Private Const WS_EX_APPWINDOW As Long = &H40000

' ----==== User32 API Deklarationen ====----
Private Declare Function GetWindowLong Lib "user32" Alias _
    "GetWindowLongA" (ByVal hWnd As Long, _
    ByVal nIndex As Long) As Long

Private Declare Function SetWindowLong Lib "user32" Alias _
    "SetWindowLongA" (ByVal hWnd As Long, _
    ByVal nIndex As Long, _
    ByVal dwNewLong As Long) As Long

'------------------------------------------------------
' Funktion     : ShowInTaskbarForm
' Beschreibung : Formular in der Taskleiste ein- oder ausblenden
' Übergabewert : Frm = Formular
'                ShowForm = True/False
'                           True = Form in der Taskleiste einblenden
'                           False = Form in der Taskleiste ausblenden
'------------------------------------------------------
Public Sub ShowInTaskbarForm(ByVal Frm As Form, _
    ByVal ShowForm As Boolean)
    
    Dim VisibleStatus As Boolean
    Dim dwLong As Long
    
    ' aktuelle Visible Eigenschaft
    ' der Form zwischenspeichern
    VisibleStatus = Frm.Visible
    
    'Form ausblenden
    Frm.Visible = False
    
    ' erweiterte Fensterstile ermitteln -> dwLong
    dwLong = GetWindowLong(Frm.hWnd, GWL_EXSTYLE)
    
    If ShowForm Then
        ' Form in der Taskleiste einblenden
        
        ' erweiterten Fensterstil WS_EX_APPWINDOW hinzufügen
        dwLong = dwLong Or WS_EX_APPWINDOW
    Else
        ' Form in der Taskleiste ausblenden
        
        ' erweiterten Fensterstil WS_EX_APPWINDOW entfernen
        dwLong = dwLong And Not WS_EX_APPWINDOW
    End If
    
    ' neuen erweiterten Fensterstil setzen
    Call SetWindowLong(Frm.hWnd, GWL_EXSTYLE, dwLong)
    
    ' zwischengespeicherte Visible
    ' Eigenschaft wiederherstellen
    Frm.Visible = VisibleStatus
End Sub
'--- Ende Modul "modShowInTaskbarForm" alias modShowInTaskbarForm.bas ---
'----------- Ende Projektdatei ShowInTaskbar.vbp  -----------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Lars Kunert am 08.12.2007 um 17:29

Wunderbar, funktioniert perfekt! Danke ;)