Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0669: Pixelgenaue Kollisionserkennung mit Regions

VB 5/6-Tipp 0669: Pixelgenaue Kollisionserkennung mit Regions

 von Zardoz

Schwierigkeitsgrad:

Verwendete API-Aufrufe: CombineRgn, CreatePolygonRgn, CreateRectRgn, DeleteObject, OffsetRgn, PaintRgn

Download: Download des Beispielprojektes [3,2 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------- Anfang Projektdatei Kollisionserkennung.vbp  -------
' Es muss ein Verweis auf 'Microsoft Scripting Runtime' gesetzt werden.

'--- Anfang Formular "frmKollisionserkennung" alias frmKollisionserkennung.frm  ---

Option Explicit


'  ----==== API Konstanten ====----

' PolyFill-Modi - von Bedeutung erst bei komplizierteren Regions
Private Const ALTERNATE As Long = 1
Private Const WINDING As Long = 2

' Verknüpfungs-Modus für CombineRgn()
Private Const RGN_AND As Long = 1

' mögliche Rückgabewerte von CombineRgn()
Private Const ERRORAPI As Long = 0
Private Const NULLREGION As Long = 1
Private Const SIMPLEREGION As Long = 2
Private Const COMPLEXREGION As Long = 3


'  ----==== API Typen ====----

'  von CreatePolygonRgn()-API erwarteter Argument-Typ
Private Type PointAPI
    x As Long
    y As Long
End Type


'  ----==== gdi32 API Deklarationen ====----

Private Declare Function DeleteObject Lib "gdi32" ( _
        ByVal hObject As Long) As Long

Private Declare Function CombineRgn Lib "gdi32" ( _
        ByVal hDestRgn As Long, _
        ByVal hSrcRgn1 As Long, _
        ByVal hSrcRgn2 As Long, _
        ByVal nCombineMode As Long) As Long

Private Declare Function CreatePolygonRgn Lib "gdi32" ( _
        lpPoint As PointAPI, _
        ByVal nCount As Long, _
        ByVal nPolyFillMode As Long) As Long

Private Declare Function PaintRgn Lib "gdi32" ( _
        ByVal hdc As Long, _
        ByVal hRgn As Long) As Long

Private Declare Function CreateRectRgn Lib "gdi32" ( _
        ByVal X1 As Long, _
        ByVal Y1 As Long, _
        ByVal X2 As Long, _
        ByVal Y2 As Long) As Long

Private Declare Function OffsetRgn Lib "gdi32" ( _
        ByVal hRgn As Long, _
        ByVal x As Long, _
        ByVal y As Long) As Long


'  ----==== private Variablen ====----

Private rgnFix As Long       ' Handle der unbeweglichen Region
Private rgnFlex As Long      ' Handle der beweglichen Region
Private rgnIntersect As Long ' Handle der Überschneidungs-Region


'  ----==== private Ereignisse ====----

Private Sub Form_Load()
    ' Regions erstellen, rgnFix zeichnen
    Dim Angle As Single
    Dim Radius As Single, MidX As Single, MidY As Single
    Dim i As Integer
    Dim Pi As Double
    Dim Figure(7) As PointAPI ' max. 8 Eckpunkte zu zeichnender Objekte

    Pi = Atn(1) * 4

    With Me
        .ScaleMode = vbPixels  ' Koordinaten-Einheit der Form: Pixel
        .AutoRedraw = True     ' Statisches Bild
        .FillStyle = vbFSSolid ' Ausgefüllt zeichnen
    End With

    ' rgnFix - 8 Eckpunkte des unbeweglichen Objekts generieren:
    MidX = Me.ScaleWidth / 2: MidY = Me.ScaleHeight / 2
    For i = 0 To 7
        Angle = 2 * Pi / 8 * (i + 0.3)
        Radius = 40 + 100 * (i And 1)
        With Figure(i)
            .x = MidX + Radius * Cos(Angle)
            .y = MidY - Radius * Sin(Angle)
        End With
    Next i
    
    ' Region erstellen
    rgnFix = CreatePolygonRgn(Figure(0), 8, ALTERNATE)
    With Me
        ' Füllfarbe
        .FillColor = vbYellow
        
        ' Region zeichnen
        Call PaintRgn(.hdc, rgnFix)
        
        ' Picture-Eigenschaft des Forms auf sein aktuelles Image setzen
        ' dadurch wird das Bild dauerhaft
        Set .Picture = .Image
    End With

    ' rgnFlex - 3 Eckpunkte des beweglichen Objekts generieren:
    ' (MidX = MidY = 0)
    Radius = 50
    For i = 0 To 2
        Angle = 2 * Pi / 3 * i
        With Figure(i)
            .x = Radius * Cos(Angle)
            .y = -Radius * Sin(Angle)
        End With
    Next i
    
    ' Region erstellen
    rgnFlex = CreatePolygonRgn(Figure(0), 3, ALTERNATE)
    
    ' Dummi-Region erstellen, die später die Überschneidung aufnimmt
    rgnIntersect = CreateRectRgn(0, 0, 0, 0)
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, _
    x As Single, y As Single)
    
    ' rgnFlex bewegen, auf Kollision mit rgnFix prüfen
    Dim CombineResult As Long
    Static OldX As Single, OldY As Single
    With Me
    
        ' Image des Forms löschen (enthält die Abbildungen von
        ' rngFlex und ggfs. rgnIntersect)
        .Cls
        
        .FillColor = vbBlue ' Füllfarbe
        
        ' rgnFlex an die neue Position verschieben
        Call OffsetRgn(rgnFlex, x - OldX, y - OldY)
        Call PaintRgn(.hdc, rgnFlex) ' Region zeichnen
        OldX = x: OldY = y           ' Position von rgnFlex merken
        
        ' Regionen mit And kombinieren, um Überschneidungen zu erkennen
        CombineResult = CombineRgn( _
            rgnIntersect, rgnFix, rgnFlex, RGN_AND)

        If CombineResult = NULLREGION Then
            .Caption = Space(20) & "Keine Kollision" ' Textausgabe
        Else
            .FillColor = vbRed ' Füllfarbe
            
            Call PaintRgn(.hdc, rgnIntersect)  ' Überschneidung rot zeichnen
            .Caption = Space(20) & "Kollision" ' Textausgabe
        End If
    End With
End Sub

Private Sub Form_Unload(Cancel As Integer)
    ' Aufräumen - Regions löschen
    Call DeleteObject(rgnFix)
    Call DeleteObject(rgnIntersect)
    Call DeleteObject(rgnFlex)
End Sub
'--- Ende Formular "frmKollisionserkennung" alias frmKollisionserkennung.frm  ---
'-------- Ende Projektdatei Kollisionserkennung.vbp  --------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 2 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.