Startseite / Tipps / VB 5/6-Tipp 0646: Freigegebene Verzeichnisse mittels NetShareEnum erfassen

VB 5/6-Tipp 0646: Freigegebene Verzeichnisse mittels NetShareEnum erfassen

 von Eckhart Wörner

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Textfeld "Text1"
' Steuerelement: Listen-Steuerelement "List1"
' Steuerelement: Schaltfläche "Command1"

Option Explicit

Private Enum eShareTyp
    Freigegebener_Ordner = 0
    Druckerwarteschlange = 1
    Device = 2
    IPC = 3
    DFS = 100
    Spezial = &H80000000
End Enum

Private Sub Command1_Click()
    Dim Shares() As tShare
    Dim i As Long
    List1.Clear
    
    ' Shares ermitteln und bei Fehler Meldung anzeigen
    If Not ErmittleShares(Text1.Text, Shares) Then
        List1.AddItem "--- Es ist ein Fehler aufgetreten ---"
        Exit Sub
    End If
    
    On Error Goto Leer
    
    For i = 0 To UBound(Shares)
        List1.AddItem "--- " + Shares(i).Name + " ---"
        
        Select Case Shares(i).Typ
        
        Case Freigegebener_Ordner
            List1.AddItem "Typ:" + vbTab + vbTab + "Freigegebener Ordner"
            
        Case Druckerwarteschlange
            List1.AddItem "Typ:" + vbTab + vbTab + "Druckerwarteschlange"
            
        Case Device
            List1.AddItem "Typ:" + vbTab + vbTab + "Device"
            
        Case IPC
            List1.AddItem "Typ:" + vbTab + vbTab + _
                "IPC (InterProcessCommunication)"
                
        Case DFS
            List1.AddItem "Typ:" + vbTab + vbTab + _
                "DFS (Distributed File System)"
            
        Case Spezial
            List1.AddItem "Typ:" + vbTab + vbTab + "Spezial"
            
        Case Else
            List1.AddItem "Typ:" + vbTab + vbTab + "Unbekannter Typ: " & _
                Shares(i).Typ
            
        End Select
        
        ' Falls keine Beschreibung existiert, lassen wir diese weg.
        If Len(Shares(i).Beschreibung) > 0 Then
            List1.AddItem "Beschreibung:" + vbTab + Shares(i).Beschreibung
        End If
        
        List1.AddItem ""
    Next i
    Exit Sub
    
Leer:
    List1.AddItem "--- Es sind keine Shares freigegeben ---"
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit

Private Declare Function NetShareEnum Lib "netapi32.dll" ( _
    ByVal servername As Long, _
    ByVal level As Long, _
    ByVal bufptr As Long, _
    ByVal prefmaxlen As Long, _
    ByRef entriesread As Long, _
    ByRef totalentries As Long, _
    ByRef resume_handle As Long _
    ) As Long
    
Private Declare Function NetApiBufferFree Lib "netapi32.dll" ( _
    ByVal buffer As Long) As Long
    
Private Declare Sub CopyMemory Lib "kernel32.dll" Alias _
    "RtlMoveMemory" (destination As Any, source As Any, _
    ByVal length As Long)
    
Private Declare Function lstrlenW Lib "kernel32.dll" ( _
    ByVal strptr As Long) As Long

Public Type tShare
    Name As String
    Typ As Long
    Beschreibung As String
End Type

Public Function ErmittleShares(ByVal Server As String, Shares() As tShare) As _
    Boolean
    Dim Gelesen As Long
    Dim Puffer As Long
    Dim Resultat As Long
    Dim ResumeHandle As Long
    Dim Total As Long
    Dim i As Long
    
    ' HINWEIS: Da wir für prefmaxlen den Wert -1 verwenden,
    ' berichtet uns die Funktion NetShareEnum wirklich alles.
    ' Aus diesem Grund ist zum einen die Variable Gelesen
    ' gleich der Variablen Total, ebenso ist ResumeHandle un-
    ' nötig, da diese nur verwendet wird, um bei zu kleinem
    ' Puffer später an der gleichen Stelle weiterzumachen,
    ' an der man aufgehört hat.
    
    Resultat = NetShareEnum(strptr(Server), 1, VarPtr(Puffer), -1, _
        Gelesen, Total, ResumeHandle)
        
'   Resultat = NetShareEnum(strptr(Server), 1, Puffer, -1, Gelesen, Total, _
        ResumeHandle)
    
    Debug.Print Resultat
    
    If Resultat = 0 And Gelesen > 0 Then
        ReDim Shares(0 To Gelesen - 1)
        For i = 0 To Gelesen - 1
            With Shares(i)
    ' Hinweis: Aus irgendeinem Grund sind selbst die Long-Variablen
    ' in der Rückgabestruktur nur Pointer, sodass wir diese über die
    ' Funktion Dereferenz_Long dereferenzieren müssen. Bei den
    ' Strings müssen wir dann gleich zwei Dereferenzierungen durch-
    ' führen: Einmal, um den Pointer zu dem Long-Wert, der als Poin-
    ' ter für den String dient, zu dereferenzieren, und dann, um
    ' diesen Long-Wert wieder zu dereferenzieren und einen String zu
    ' erhalten.
    ' Die Variable Puffer liefert uns einen Pointer auf ein Array
    ' von SHARE_INFO_1-Strukturen. Dieses besteht aus drei Long-
    ' Werten, damit ist eine Struktur 12 Byte groß. Wir springen
    ' deshalb auch jedesmal 12 Byte weiter.
                .Name = Dereferenz_String(Dereferenz_Long(Puffer + 12 * i))
                .Typ = Dereferenz_Long(Puffer + 12 * i + 4)
                .Beschreibung = Dereferenz_String(Dereferenz_Long(Puffer + 12 _
                    * i + 8))
            End With
        Next i
        
        ErmittleShares = True
    End If
    
    ' Falls NetShareEnum Speicher belegt hat, muss dieser wieder freigegeben
    ' werden
    If CBool(Puffer) Then
       NetApiBufferFree Puffer
    End If
End Function

' Dereferenzierung eines Pointer auf einen Long
Private Function Dereferenz_Long(ByVal Pointer As Long) As Long
    Call CopyMemory(Dereferenz_Long, ByVal Pointer, 4)
End Function

' Dereferenzierung eines Pointers auf einen String
Private Function Dereferenz_String(ByVal Pointer As Long) As String
    Dim Laenge As Long
    Dim Puffer() As Byte
    
    If CBool(Pointer) Then
        Laenge = lstrlenW(Pointer) * 2
        If CBool(Laenge) Then
            ReDim Puffer(Laenge - 1) As Byte
            CopyMemory Puffer(0), ByVal Pointer, Laenge
            Dereferenz_String = Puffer
        End If
    End If
End Function
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 11 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.