Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0601: Aktuelle Zeile und Zelle im Flexgrid markieren

 von 

Beschreibung 

Diverse Tabellenkalkulationsprogramme heben die gerade ausgewählte Zelle farblich hervor. Natürlich lässt sich solch ein Verhalten mit wenigen Kniffen auch in VB realisieren.

Schwierigkeitsgrad:

Schwierigkeitsgrad 1

Verwendete API-Aufrufe:

keine

Download:

Download des Beispielprojektes [2,67 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
' Die Komponente 'Microsoft FlexGrid Control 6.0 (MSFLXGRD.OCX)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Kontrollkästchen-Steuerelement "Check1"
' Steuerelement: Flexible Tabelle "MSFlexGrid1"


'---------------------------------------------------------
'
'     Flexgrid aktuelle Zeile und aktuelle Zelle markieren
'
'     by peter.k.sauer@web.de  05.2003
'---------------------------------------------------------

Option Explicit

'zuletzt angeclickte Zeile im Flexgrid
Private FlexLastSelectedRow As Long

'Darstellung der aktiven Zelle
Private FlexNotActiveCell As Boolean

Private Sub Check1_Click()
    FlexNotActiveCell = Check1.Value * -1
    MSFlexGrid1_SelChange
          
    On Error Resume Next
    MSFlexGrid1.SetFocus
End Sub

Private Sub Form_Load()
   Dim i As Long, j As Long
   
   'ein Flexgrid einstellen
   With MSFlexGrid1
        
        'kräftiger Rahmen aktive Zelle
        .FocusRect = flexFocusHeavy
        .SelectionMode = flexSelectionFree
        .FillStyle = flexFillRepeat
       
        .Rows = 30
        .Cols = 6
       
        'Texte zum Test übergeben
        For i = .FixedRows To .Rows - 1
            For j = .FixedCols To .Cols - 1
                .TextMatrix(i, j) = "Hallo"
            Next j
        Next i
        
        'Cursor auf 1. editierbare Zelle
        .Row = .FixedRows
        .Col = .FixedCols
        
        FlexLastSelectedRow = .Row
    End With
    
    'Checkbox einstellen
    Check1.Caption = "NotActiveCell"
    Check1.Value = 1
End Sub

Private Sub MSFlexGrid1_SelChange()
    FlexMarkActiveRowAndActiveCell MSFlexGrid1, FlexLastSelectedRow, FlexNotActiveCell
End Sub

Public Sub FlexMarkActiveRowAndActiveCell(Flexgrid As MSFlexGrid, _
    FlexLastSelectedRow As Long, Optional NotActiveCell As Boolean = True)
    
    'aktuelle Zeile und aktuelle Zelle einfärben
    Static IsLocked As Boolean
    Dim Row As Long
    Dim Col As Long
    
    'rekursiven Aufruf unterbinden
    If IsLocked Then
        Exit Sub
    End If
    
    
    IsLocked = True
    With MSFlexGrid1
         
        'neuzeichnen unterbinden
        .Redraw = False
        
        'Position sichern
        Row = .Row
        Col = .Col
        
        'zuletzt markierte Zeile normal darstellen
        .Row = FlexLastSelectedRow
        .Col = .FixedCols
        .ColSel = .Cols - 1
        .CellBackColor = .BackColor
        .CellForeColor = .ForeColor
        
        'aktuelle Zeile einfärben
        .Row = Row
        .Col = .FixedCols
        .ColSel = .Cols - 1
        .CellBackColor = .BackColorSel
        .CellForeColor = .ForeColorSel
        
        'gewählte Zelle einstellen
        .Row = Row
        .Col = Col
         
        'die gewählte Zelle normal darstellen
        If NotActiveCell Then
            .CellBackColor = .BackColor
            .CellForeColor = .ForeColor
        End If
         
        .Redraw = True
    End With
    
    'sichern der aktuellen Zeile
    FlexLastSelectedRow = Row
     
    'freigeben Ereignis
    IsLocked = False
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 2 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von D.I. am 06.06.2007 um 09:36

Wenn mein flexgrid kein fixe column hat, wie kann ich die erste Kolonne selektieren

Kommentar von Stefan am 01.08.2005 um 17:13

Hallo,

die Routine wäre sehr interessant aber sie funktioniert nicht wenn man die Sortierreihenfolge nachträglich ändert!
FlexLastSelectedRow hat danach einen falschen Wert.

Grüße Stefan