Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0570: DynDns-Konto Updaten

VB 5/6-Tipp 0570: DynDns-Konto Updaten

 von NoOne

Schwierigkeitsgrad:

Verwendete API-Aufrufe: keine

Download: Download des Beispielprojektes [2,47 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Textfeld "Text6"
' Steuerelement: Textfeld "Text5"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Kontrollkästchen-Steuerelement "Check2"
' Steuerelement: Textfeld "Text4"
' Steuerelement: Kontrollkästchen-Steuerelement "Check1"
' Steuerelement: Textfeld "Text3"
' Steuerelement: Textfeld "Text2"
' Steuerelement: Textfeld "Text1"
' Steuerelement: Beschriftungsfeld "Label7"
' Steuerelement: Beschriftungsfeld "Label6"
' Steuerelement: Beschriftungsfeld "Label5"
' Steuerelement: Beschriftungsfeld "Label4"
' Steuerelement: Beschriftungsfeld "Label3"

Option Explicit

Private Sub UpdateDynDns(User As String, _
                        Pass As String, _
                        Host As String, _
                        AutoIp As Boolean, _
                        Ip As String, _
                        WildCard As Boolean)
    
    Dim xmlhttp As Object
    Dim url As String
    
    Set xmlhttp = CreateObject("microsoft.xmlhttp")
    url = "https://" & User & ":" & Pass
    url = url & "@members.dyndns.org/nic/update?system=dyndns&hostname=" & Host
    
    url = url & "&myip="
    If AutoIp = False Then
      url = url & Ip
    End If
    
    url = url & "&wildcard="
    If WildCard Then
      url = url & "on"
    Else
      url = url & "off"
    End If
    
    Text5 = url
    xmlhttp.Open "get", url, False
    xmlhttp.setrequestheader "Pragma", "no-cache"
    xmlhttp.setrequestheader "Cache-control", "no-cache"
    
    On Error Resume Next
    xmlhttp.send
    
    If Err.Number <> 0 Then
        Text6 = "Fehler!"
        Exit Sub
    End If
    
    On Error Goto 0
    If xmlhttp.Status = 200 Then
        Text6 = CStr(xmlhttp.responsetext)
    Else
        If xmlhttp.Status = 401 Then
            Text6 = "Fehler beim Autorisieren"
        Else
            Text6 = "Fehler"
        End If
    End If
End Sub

Private Sub Check1_Click()
  Text4.Enabled = (Check1.Value = 0)
End Sub

Private Sub Command1_Click()
  If Len(Text1) = 0 Then
    MsgBox "Bitte geben Sie erst einen Benutzernamen ein!"
    Exit Sub
  End If
  
  If Len(Text2) = 0 Then
    MsgBox "Bitte geben Sie erst ein Passwort ein!"
    Exit Sub
  End If

  If Len(Text3) = 0 Then
    MsgBox "Bitte geben Sie erst einen Hostnamen ein!"
    Exit Sub
  End If
  
  If Check1.Value = 0 And Len(Text4) = 0 Then
    MsgBox "Bitte geben Sie erst eine IP-Adresse ein!"
    Exit Sub
  End If
  
  UpdateDynDns Text1, Text2, Text3, (Check1.Value = 1), Text4, (Check2.Value = 1)
End Sub

Private Sub Form_Load()

End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.