Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0549: eine URL en- und decodieren

VB 5/6-Tipp 0549: eine URL en- und decodieren

 von Benjamin Wilger

Schwierigkeitsgrad:

Verwendete API-Aufrufe: keine

Download: Download des Beispielprojektes [2,65 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Textfeld "Text2"
' Steuerelement: Textfeld "Text1"
' Steuerelement: Beschriftungsfeld "Label1"
' Steuerelement: Beschriftungsfeld "Label2"
Option Explicit



Private Sub Command1_Click()
    Text2.Text = URLEncode(Text1.Text)
End Sub

Private Sub Command2_Click()
    Text2.Text = URLDecode(Text1.Text)
End Sub

'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------
Option Explicit
'Copyright (C) 2002 by Benjamin Wilger
'Kontakt: Benjamin Wilger

'Gibt einen Hex-String mit führenden Nullen zurück.
Private Function toHex(ByVal Number As Long, _
                       ByVal NumLen As Integer, _
                        Optional ByVal UpperCase As Boolean) As String
    
    Dim C As String
    
    C = Hex(Number)

    If Len(C) < NumLen Then
        C = String(NumLen - Len(C), "0") & C
    End If
 
    If Not UpperCase Then
        toHex = LCase(C)
    Else
        toHex = C
    End If
 
End Function

' String URLEncoden
Public Function URLEncode(ByVal strInput As String) As String
    Dim strResult, lngChar As Long
    
    Do While Len(strInput) > 0
        lngChar = Asc(strInput)
        strInput = Right(strInput, Len(strInput) - 1)
        If (lngChar >= Asc("a") And lngChar <= Asc("z")) Or _
            (lngChar >= Asc("A") And lngChar <= Asc("Z")) Or _
            (lngChar >= Asc("0") And lngChar <= Asc("9")) Then
            strResult = strResult & Chr(lngChar)
        ElseIf lngChar = Asc(" ") Then
            strResult = strResult & "+"
        Else
            strResult = strResult & "%" & toHex(lngChar, 2)
        End If
    Loop
    
    URLEncode = strResult
End Function

' String URLDecoden
Public Function URLDecode(ByVal strInput As String) As String
    Dim strResult, lngChar As Long, strChar As String
    Dim i As Long
    
    For i = 1 To Len(strInput)
        strChar = Mid$(strInput, i, 1)
        If strChar = "+" Then
            strResult = strResult & " "
        ElseIf strChar = "%" Then
            strResult = strResult & _
            Chr(Val("&H" & Mid$(strInput, i + 1, 1) & _
            Mid$(strInput, i + 2, 1)))
            i = i + 2 'Zwei Zeichen überspringen
        Else
            strResult = strResult & strChar
        End If
    Next i
    
    URLDecode = strResult
End Function
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.