Startseite / Tipps / VB 5/6-Tipp 0501: Datei per HTTP uploaden

VB 5/6-Tipp 0501: Datei per HTTP uploaden

 von Peter Molnar

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Textfeld "txtFile"
' Steuerelement: Textfeld "txtUrl"
' Steuerelement: Textfeld "txtServer"
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Beschriftungsfeld "Label4"
' Steuerelement: Beschriftungsfeld "Label3"
' Steuerelement: Beschriftungsfeld "Label2"
' Steuerelement: Beschriftungsfeld "Label1"
' von Peter Molnar (peter.molnar@wm.sk)
'
' Auf dem Server wird noch ein Script
' zum empfangen der Dateien benötigt.
' Hier ein kleines PHP-Script:
'
' <?
' echo "-[$variable1]-[$variable2]-".is_uploaded_file($datei)."-";
' copy ($HTTP_POST_FILES['datei']['tmp_name'],"c:/temp/test.gif");
' ?>



Private Declare Function InternetOpen Lib "wininet.dll" _
    Alias "InternetOpenA" _
    (ByVal lpszCallerName As String, _
    ByVal dwAccessType As Long, _
    ByVal lpszProxyName As String, _
    ByVal lpszProxyBypass As String, _
    ByVal dwFlags As Long) As Long

Private Declare Function InternetConnect Lib "wininet.dll" _
    Alias "InternetConnectA" _
    (ByVal hInternetSession As Long, _
    ByVal lpszServerName As String, _
    ByVal nProxyPort As Integer, _
    ByVal lpszUsername As String, _
    ByVal lpszPassword As String, _
    ByVal dwService As Long, _
    ByVal dwFlags As Long, _
    ByVal dwContext As Long) As Long

Private Declare Function InternetReadFile Lib "wininet.dll" _
    (ByVal hFile As Long, _
    ByVal sBuffer As String, _
    ByVal lNumBytesToRead As Long, _
    lNumberOfBytesRead As Long) As Integer

Private Declare Function HttpOpenRequest Lib "wininet.dll" _
    Alias "HttpOpenRequestA" _
    (ByVal hInternetSession As Long, _
    ByVal lpszVerb As String, _
    ByVal lpszObjectName As String, _
    ByVal lpszVersion As String, _
    ByVal lpszReferer As String, _
    ByVal lpszAcceptTypes As Long, _
    ByVal dwFlags As Long, _
    ByVal dwContext As Long) As Long

Private Declare Function HttpSendRequest Lib "wininet.dll" _
    Alias "HttpSendRequestA" _
    (ByVal hHttpRequest As Long, _
    ByVal sHeaders As String, _
    ByVal lHeadersLength As Long, _
    ByVal sOptional As String, _
    ByVal lOptionalLength As Long) As Boolean

Private Declare Function InternetCloseHandle Lib "wininet.dll" _
    (ByVal hInternetHandle As Long) As Boolean

Private Declare Function HttpAddRequestHeaders Lib "wininet.dll" _
    Alias "HttpAddRequestHeadersA" _
    (ByVal hHttpRequest As Long, _
    ByVal sHeaders As String, _
    ByVal lHeadersLength As Long, _
    ByVal lModifiers As Long) As Integer

Private Const INTERNET_OPEN_TYPE_PRECONFIG = 0
Private Const INTERNET_SERVICE_HTTP = 3
Private Const INTERNET_DEFAULT_HTTP_PORT = 80
Private Const INTERNET_FLAG_RELOAD = &H80000000
Private Const HTTP_ADDREQ_FLAG_ADD = &H20000000
Private Const HTTP_ADDREQ_FLAG_REPLACE = &H80000000


' Gibt TRUE zuruck wenn die datei erfolgreich gepostet wurde.
' Anderenfalls gibt FALSE zuruck.
' Die antwort des skripts wird in ptrResult geschrieben.
' Beispiel: c:\autoexec.bat ans Skript http://www.dom.de/uploadPic.php schicken:
' httpPostFile("www.dom.de","/uploadPic.php","c:\autoexec.bat",result$)

Private Function httpPostFile(server$, url$, file$, ByRef ptrResult$) As Boolean

Dim hInternetOpen&, hInternetConnect&, hHttpOpenRequest&, lNumberOfBytesRead&
Dim bRet As Boolean, bDoLoop As Boolean
Dim sReadBuffer As String * 2048, sPostData$
Dim nFile%

On Error Goto errorLabel

hInternetOpen = 0
hInternetConnect = 0
hHttpOpenRequest = 0

hInternetOpen = InternetOpen(App.EXEName, INTERNET_OPEN_TYPE_PRECONFIG, _
    vbNullString, vbNullString, 0)

If hInternetOpen = 0 Then Goto errorLabel

hInternetConnect = InternetConnect(hInternetOpen, server, INTERNET_DEFAULT_HTTP_PORT, _
    vbNullString, "HTTP/1.0", INTERNET_SERVICE_HTTP, 0, 0)

If hInternetConnect = 0 Then Goto errorLabel

hHttpOpenRequest = HttpOpenRequest(hInternetConnect, "POST", url, "HTTP/1.0", _
    vbNullString, 0, INTERNET_FLAG_RELOAD, 0)

If hHttpOpenRequest = 0 Then Goto errorLabel

sHeader = "Content-Type: multipart/form-data, boundary=AaB03x" & vbCrLf
bRet = HttpAddRequestHeaders(hHttpOpenRequest, sHeader, Len(sHeader), _
    HTTP_ADDREQ_FLAG_REPLACE Or HTTP_ADDREQ_FLAG_ADD)

'Datei zum posten in einen string lesen
nFile = FreeFile
Open file For Binary As #nFile
    sPostData = String(LOF(nFile), " ")
    Get #nFile, , sPostData
Close #nFile

'Die datei posten
sPostData = _
"--AaB03x" & vbCrLf & _
"Content-Disposition: form-data; name=""datei""; filename=""" & file & """" & vbCrLf & _
"Content-Transfer-Encoding: binary" & vbCrLf & _
"Content-Type: application/octet-stream" & vbCrLf & vbCrLf & _
sPostData & vbCrLf

'Noch zwei andere variablen posten
sPostData = sPostData & _
"--AaB03x" & vbCrLf & _
"Content-Disposition: form-data; name=""variable1""" & vbCrLf & vbCrLf & _
"meine variable numero uno" & vbCrLf & _
"--AaB03x" & vbCrLf & _
"Content-Disposition: form-data; name=""variable2""" & vbCrLf & vbCrLf & _
"meine variable zwei" & vbCrLf & _
"--AaB03x--"

bRet = HttpSendRequest(hHttpOpenRequest, vbNullString, 0, sPostData, Len(sPostData))

ptrResult = ""

Do
    sReadBuffer = vbNullString
    bDoLoop = InternetReadFile(hHttpOpenRequest, sReadBuffer, Len(sReadBuffer), lNumberOfBytesRead)
    ptrResult = ptrResult & Left(sReadBuffer, lNumberOfBytesRead)
    If Not CBool(lNumberOfBytesRead) Or Not bDoLoop Then Exit Do
Loop

httpPostFile = True
Goto closeHandles

errorLabel:
httpPostFile = False

closeHandles:

If hInternetOpen <> 0 Then InternetCloseHandle hInternetOpen
If hInternetConnect <> 0 Then InternetCloseHandle hInternetConnect
If hHttpOpenRequest <> 0 Then InternetCloseHandle hHttpOpenRequest
End Function

Private Sub Command2_Click()
Dim strResult As String
httpPostFile txtServer.Text, txtUrl.Text, txtFile.Text, strResult
MsgBox strResult
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 16 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.