Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0481: Verknüpfungen über den Windows Scripting Host erstellen

VB 5/6-Tipp 0481: Verknüpfungen über den Windows Scripting Host erstellen

 von Patrick Gründer

Schwierigkeitsgrad:

Verwendete API-Aufrufe: keine

Download: Download des Beispielprojektes [2,14 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
Option Explicit

Private Enum Modus
    SW_HIDE = 0
    SW_MINIMIZE = 6
    SW_RESTORE = 9
    SW_SHOW = 5
    SW_SHOWMAXIMIZED = 3
    SW_SHOWMINIMIZED = 2
    SW_SHOWMINNOACTIVE = 7
    SW_SHOWNA = 8
    SW_SHOWNOACTIVATE = 4
    SW_SHOWNORMAL = 1
End Enum

Private Sub Command1_Click()
    Call Verknüpfung("C:\Windows\Notepad.exe", "C:", "Verknüpfung mit Notepad", "", _
        "Das ist eine Verknüpfung mit Notepad!", SW_SHOWNORMAL, "CTRL+ALT+N")
End Sub

Private Function Verknüpfung( _
        ProgrammPfad As String, _
        PfadDerVerknüpfung As String, _
        NameDerVerknüpfung As String, _
        Parameter As String, _
        Beschreibung As String, _
        Fenstermodus As Modus, _
        Tastenkombination As String)
    
    Dim objWshShell As Object
    Dim objMyShortCut As Object
    Dim StrPath As String
    Dim ProgrammPfadA As String
    
    Set objWshShell = CreateObject("Wscript.Shell")
    Set objMyShortCut = objWshShell.CreateShortcut(PfadDerVerknüpfung & "\" & _
        NameDerVerknüpfung & ".lnk")
    
    ProgrammPfadA = StrReverse(ProgrammPfad)
    StrPath = Mid$(ProgrammPfadA, InStr(1, ProgrammPfadA, "\", vbBinaryCompare) + 1)
    StrPath = StrReverse(StrPath)
    
    objMyShortCut.TargetPath = ProgrammPfad
    objMyShortCut.IconLocation = ProgrammPfad
    objMyShortCut.Arguments = Parameter
    objMyShortCut.Description = Beschreibung
    objMyShortCut.WindowStyle = Fenstermodus
    objMyShortCut.WorkingDirectory = StrPath
    objMyShortCut.HotKey = Tastenkombination
    objMyShortCut.Save
    
    Set objMyShortCut = Nothing
    Set objWshShell = Nothing
End Function
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------