Startseite / Tipps / VB 5/6-Tipp 0411: Komplexe Tastenkombination als Hotkey registrieren

VB 5/6-Tipp 0411: Komplexe Tastenkombination als Hotkey registrieren

 von Kopczynski

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Die Komponente 'Microsoft Windows Common Controls 5.0 (SP2) (comctl32.ocx)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Beschriftungsfeld "Label5"


'Autor: Kopczynski
'E-Mail: D.Copy@gmx.de

Option Explicit

Private Sub Form_Load()
    Call SetHotKey(Me.hWnd, &H1 + &H2, &H77)
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Call RemoveHotKey
End Sub

Private Sub Command1_Click()
    App.TaskVisible = False
    Me.Hide
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit

Private Declare Function RegisterHotKey Lib "user32" (ByVal _
        hWnd As Long, ByVal id As Long, ByVal fsModifiers As _
        Long, ByVal vk As Long) As Long
        
Private Declare Function UnregisterHotKey Lib "user32" (ByVal _
        hWnd As Long, ByVal id As Long) As Long

Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hWnd As Long, ByVal Msg As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
        
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Private Declare Function GlobalDeleteAtom Lib "kernel32" _
        (ByVal nAtom As Integer) As Integer
        
Private Declare Function GlobalAddAtom Lib "kernel32" Alias _
        "GlobalAddAtomA" (ByVal lpString As String) As Integer

Const GWL_WNDPROC As Long = (-4&)
Const WM_HOTKEY As Long = &H312&

Public Enum ModKeys
    MOD_ALT = &H1
    MOD_CONTROL = &H2
    MOD_SHIFT = &H4
    MOD_WIN = &H8
End Enum

Private OldProc As Long, hOwner As Long
Private iAtom As Integer

Public Sub SetHotKey(hWnd As Long, ModKey As ModKeys, _
                          vKey As Long)
    
    hOwner = hWnd
    
    iAtom = GlobalAddAtom("MyHotKey")
    Call RegisterHotKey(hOwner, iAtom, ModKey, vKey)
    
    OldProc = SetWindowLong(hOwner, GWL_WNDPROC, _
              AddressOf WndProc)
    
End Sub

Public Sub RemoveHotKey()
    If hOwner = 0 Then Exit Sub
    Call UnregisterHotKey(hOwner, iAtom)
    Call SetWindowLong(hOwner, GWL_WNDPROC, OldProc)
    Call GlobalDeleteAtom(iAtom)
End Sub

Public Function WndProc(ByVal hWnd As Long, _
        ByVal wMsg As Long, ByVal wParam As Long, _
        ByVal lParam As Long) As Long
                        
    If wMsg = WM_HOTKEY And wParam = iAtom Then
        Form1.Show
    Else
        WndProc = CallWindowProc(OldProc, hWnd, wMsg, wParam, lParam)
    End If
End Function
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 9 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.