Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0302: Den Standard-Progressbar beliebig einfärben

VB 5/6-Tipp 0302: Den Standard-Progressbar beliebig einfärben

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: SendMessageA (SendMessage)

Download: Download des Beispielprojektes [2,29 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Die Komponente 'Microsoft Windows Common Controls 6.0 (SP6) (MSCOMCTL.OCX)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Timersteuerelement "Timer1"
' Steuerelement: Fortschrittsanzeige "ProgressBar1"

Option Explicit
         
Private Declare Function SendMessage Lib "user32" Alias _
        "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As _
        Long, ByVal wParam As Long, ByVal lParam As Long) _
        As Long

Const PBM_SETBARCOLOR = &H409
Const PBM_SETBKCOLOR = &H2001

Private Sub Form_Load()
  ProgressBar1.Min = 0
  ProgressBar1.Max = 100
  ProgressBar1.Value = 0
  Timer1.Interval = 50
  Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
  Dim f&
  Static z%, k%
  Const s% = 8
  
    With ProgressBar1
      If k = 0 Then k = s
      
      z = z + k
      If k > 0 Then
        If z > .Max - 1 Then
          k = -s
          z = .Max
        End If
      Else
        If z < .Min + 1 Then
          k = s
          z = .Min
        End If
      End If
      
      .Value = z
      f = 255 / .Max * z
      Call ChangeBarColor(.hwnd, RGB(f, 0, 0), _
                          RGB(0, 0, 255 - f))
    End With
End Sub

Private Sub ChangeBarColor(pbhWnd&, ForeCol&, BackCol&)
  Call SendMessage(pbhWnd, PBM_SETBARCOLOR, 0&, ForeCol)
  Call SendMessage(pbhWnd, PBM_SETBKCOLOR, 0&, BackCol)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 2 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.