Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0285: Label mit Hover-Effekt als Link nutzen

 von 

Beschreibung 

Immer wieder gefragt, ein Möglichkeit der Einbindung eines Links in VB. Mit einem einfachen Label läßt sich sogar der bekannte Hover-Effekt und das typische ThumbNail-Icon bewerkstelligen.

Schwierigkeitsgrad:

Schwierigkeitsgrad 1

Verwendete API-Aufrufe:

ClientToScreen, GetCursorPos, ShellExecuteA (ShellExecute)

Download:

Download des Beispielprojektes [3,59 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Timersteuerelement "Timer1"
' Steuerelement: Anzeige-Steuerelement "Image1"
' Steuerelement: Beschriftungsfeld "Label1"

Option Explicit

Private Declare Function GetCursorPos Lib "user32" _
        (lpPoint As POINTAPI) As Long
        
Private Declare Function ClientToScreen Lib "user32" _
        (ByVal hwnd As Long, lpPoint As POINTAPI) As Long
        
Private Declare Function ShellExecute Lib "shell32.dll" _
        Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal _
        lpOperation As String, ByVal lpFile As String, ByVal _
        lpParameters As String, ByVal lpDirectory As String, _
        ByVal nShowCmd As Long) As Long

Private Type POINTAPI
  X As Long
  y As Long
End Type

Dim MOver As Boolean

Private Sub Form_Load()
  Label1.MouseIcon = LoadPicture(App.Path & "\Hand.cur")
End Sub

Private Sub Label1_Click()
  Call ShellExecute(Me.hwnd, "Open", "http://www.activevb.de", _
                    "", App.Path, 1)
End Sub

Private Sub Label1_MouseDown(Button As Integer, Shift As Integer, _
                             X As Single, y As Single)
  Label1.ForeColor = RGB(0, 160, 160)
End Sub

Private Sub Label1_MouseUp(Button As Integer, Shift As Integer, _
                           X As Single, y As Single)
  Label1.ForeColor = RGB(0, 80, 80)
End Sub

Private Sub Label1_MouseMove(Button As Integer, Shift As Integer, _
                             X As Single, y As Single)
  If Not MOver Then
    Label1.FontUnderline = True
    MOver = True
  End If
End Sub

Private Sub Timer1_Timer()
  Dim x1&, y1&, x2&, y2&
  Dim P As POINTAPI
    
    If MOver Then
      Call ClientToScreen(Me.hwnd, P)
      x1 = P.X + Label1.Left / Screen.TwipsPerPixelX
      y1 = P.y + Label1.Top / Screen.TwipsPerPixelX
      x2 = x1 + Label1.Width / Screen.TwipsPerPixelX
      y2 = y1 + Label1.Height / Screen.TwipsPerPixelX
      Call GetCursorPos(P)
      If P.X < x1 Or P.X > x2 Or P.y < y1 Or P.y > y2 Then
        Label1.FontUnderline = False
        MOver = False
      End If
    End If
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 2 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Tom am 10.10.2003 um 20:09

Tipp:

Wenn du statt auf eine Web-Page auf eine Email-Adresse verweisen möchtest, dann verwende Folgendes:

Call ShellExecute (Me.hwnd, "Open", "mailto:Tipps@ActiveVB.de", _
"", App.Path, 1)


LG Tom

Kommentar von Carsten am 27.03.2002 um 16:53

Im Form_Load Ereignis sollte noch Label1.MousePointer = 99 eingetragen werden, damit es funktioniert