Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0213: Fensterstile zur Laufzeit ändern

VB 5/6-Tipp 0213: Fensterstile zur Laufzeit ändern

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: GetWindowLongA (GetWindowLong), GetWindowRect, SetWindowLongA (SetWindowLong), SetWindowPos

Download: Download des Beispielprojektes [2,32 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Kontrollkästchen-Steuerelement "Check1" (Index von 0 bis 4)

Option Explicit

Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Private Declare Function GetWindowLong Lib "user32" Alias _
        "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex _
        As Long) As Long
        
Private Declare Function SetWindowPos Lib "user32" (ByVal _
        hWnd As Long, ByVal hWndInsertAfter As Long, ByVal _
        x As Long, ByVal y As Long, ByVal cx As Long, _
        ByVal cy As Long, ByVal wFlags As Long) As Long
       
Private Declare Function GetWindowRect Lib "user32" (ByVal _
        hWnd As Long, lpRect As Rect) As Long
        
Private Type Rect
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

Const SWP_FRAMECHANGED = &H20
Const GWL_STYLE = (-16)
Const WS_MAXIMIZEBOX = &H10000
Const WS_MINIMIZEBOX = &H20000
Const WS_THICKFRAME = &H40000
Const WS_SYSMENU = &H80000
Const WS_HSCROLL = &H100000
Const WS_VSCROLL = &H200000
Const WS_BORDER = &H800000

Private Sub Check1_Click(Index As Integer)
  Select Case Index
    Case 0: Call SetForm(WS_MAXIMIZEBOX, False)
            Call SetForm(WS_MINIMIZEBOX, True)
    Case 1: Call SetForm(WS_SYSMENU, True)
    Case 2: Call SetForm(WS_VSCROLL, True)
            Call SetForm(WS_HSCROLL, True)
    Case 3: Call SetForm(WS_BORDER, True)
    Case 4: Call SetForm(WS_THICKFRAME, True)
  End Select
End Sub

Private Sub SetForm(ToggleStyle&, FRefresh As Boolean)
  Dim lngStyle&, R As Rect
  
    lngStyle = GetWindowLong(Me.hWnd, GWL_STYLE)
    If (lngStyle And ToggleStyle&) Then
      lngStyle = lngStyle - ToggleStyle&
    Else
      lngStyle = lngStyle Or ToggleStyle&
    End If
    Call SetWindowLong(Me.hWnd, GWL_STYLE, lngStyle)
    Call GetWindowRect(Me.hWnd, R)
    Call SetWindowPos(Me.hWnd, 0, R.Left, R.Top, _
         R.Right - R.Left, R.Bottom - R.Top, _
         SWP_FRAMECHANGED)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.