Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0146: ComboBox mit CheckBox im Eingabefeld versehen

VB 5/6-Tipp 0146: ComboBox mit CheckBox im Eingabefeld versehen

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: FindWindowExA (FindWindowEx), SendMessageA (SendMessage)

Download: Download des Beispielprojektes [2,18 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Kombinationsliste "Combo1"
' Steuerelement: Kontrollkästchen-Steuerelement "Check1"

Option Explicit

Private Declare Function SendMessage Lib "user32" _
        Alias "SendMessageA" (ByVal hwnd As Long, ByVal _
        wMsg As Long, ByVal wParam As Long, ByVal lParam _
        As Long) As Long
        
Private Declare Function FindWindowEx Lib "user32" _
        Alias "FindWindowExA" (ByVal hwndParent As _
        Long, ByVal hwndChildAfter As Long, ByVal _
        lpszClass As String, ByVal lpszWindow As _
        String) As Long

Const EC_LEFTMARGIN = &H1
Const EM_SETMARGINS = &HD3

Private Sub Form_Load()
  Dim TPX%, TexthWnd&, MrgnLeft&
    
    TPX = Screen.TwipsPerPixelX
    
    With Combo1
      .AddItem "Zwiebeln"
      .AddItem "Knofi"
      .AddItem "Gurken"
      .AddItem "Tomaten"
    
      TexthWnd = FindWindowEx(.hwnd, 0, "EDIT", vbNullString)
    
      If (TexthWnd <> 0) Then
        MrgnLeft = Check1.Width / TPX + 4
        Call SendMessage(TexthWnd, EM_SETMARGINS, EC_LEFTMARGIN, _
                         MrgnLeft)
      
        Check1.BackColor = .BackColor
        Check1.Move .Left + 4 * TPX, .Top + 2 * TPX, Check1.Width, _
                    .Height - 4 * TPX
        Check1.ZOrder 0
      End If
    End With
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.