Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0140: Grafiken in Menüs

VB 5/6-Tipp 0140: Grafiken in Menüs

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: GetMenu, GetMenuItemID, GetSubMenu, ModifyMenuA (ModifyMenu)

Download: Download des Beispielprojektes [3,35 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project.vbp  -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Bildfeld-Steuerelement "Picture1" (Index von 0 bis 0)
' Steuerelement: Menü "mnuMenü"
' Steuerelement: Menü "mnuLeer" (Index von 0 bis 0) auf mnuMenü

Option Explicit

Private Declare Function GetMenu Lib "user32" (ByVal _
        hwnd As Long) As Long
        
Private Declare Function GetSubMenu Lib "user32" (ByVal _
        hMenu As Long, ByVal nPos As Long) As Long
        
Private Declare Function GetMenuItemID Lib "user32" (ByVal _
        hMenu As Long, ByVal nPos As Long) As Long
        
Private Declare Function ModifyMenu Lib "user32" Alias _
        "ModifyMenuA" (ByVal hMenu As Long, ByVal nPosition _
        As Long, ByVal wFlags As Long, ByVal wIDNewItem As _
        Long, ByVal lpString As Any) As Long

Const MF_BYCOMMAND = &H0&
Const MF_BITMAP = &H4&

Private Sub Form_Load()
  Dim X%, h1&, h2&, Com&
    h1 = GetMenu(Me.hwnd)
    h2 = GetSubMenu(h1, 0)
    
    For X = 1 To 9
      Load mnuLeer(X)
      Load Picture1(X)
    Next X
    
    For X = 0 To 255
      Picture1(0).Line (X * 15, 0)-(X * 15, _
                       Picture1(0).Height), RGB(X, 0, 0)
      Picture1(1).Line (X * 15, 0)-(X * 15, _
                       Picture1(1).Height), RGB(0, X, 0)
      Picture1(2).Line (X * 15, 0)-(X * 15, _
                       Picture1(2).Height), RGB(0, 0, X)
      Picture1(3).Line (X * 15, 0)-(X * 15, _
                       Picture1(0).Height), RGB(X, 0, X)
      Picture1(4).Line (X * 15, 0)-(X * 15, _
                       Picture1(0).Height), RGB(0, X, X)
    Next X
 
    For X = 5 To 9
      Picture1(X).Font.Name = Screen.Fonts(X)
      Picture1(X).Height = Picture1(X).TextHeight(Screen.Fonts(X))
      Picture1(X).Print Screen.Fonts(X)
    Next X
 
    For X = 0 To 9
      Picture1(X).Picture = Picture1(X).Image
      Com = GetMenuItemID(h2, X)
      Call ModifyMenu(h2, Com, MF_BYCOMMAND Or MF_BITMAP, _
                      Com, CLng(Picture1(X).Picture))
    Next X
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Dim X%
    For X = 1 To 9
      Unload Picture1(X)
      Unload mnuLeer(X)
    Next X
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project.vbp  --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 6 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.