Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0137: Defaultitem im Menü setzen

 von 

Beschreibung 

Was meines Wissens von VB aus nicht geht, ist das Setzen eines Default-Items in Menüs (fett hervorgehobener Eintrag) Dabei bietet Windows die Möglichkeit dies für jeweils einen Punkt pro Menü zu realisieren. Hier wird gezeigt wie es geht.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

CallWindowProcA (CallWindowProc), GetMenu, GetMenuDefaultItem, GetMenuStringA (GetMenuString), GetSubMenu, SetMenuDefaultItem, SetWindowLongA (SetWindowLong)

Download:

Download des Beispielprojektes [2,72 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit

Private Declare Function GetMenuDefaultItem Lib "user32" _
        (ByVal hMenu As Long, ByVal fByPos As Long, ByVal _
        gmdiFlags As Long) As Long

Private Declare Function SetMenuDefaultItem Lib "user32" _
        (ByVal hMenu As Long, ByVal uItem As Long, ByVal _
        fByPos As Long) As Long
              
Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hwnd As Long, ByVal MSG As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
        
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Private Declare Function GetMenu Lib "user32" (ByVal _
        hwnd As Long) As Long
        
Private Declare Function GetSubMenu Lib "user32" (ByVal _
        hMenu As Long, ByVal nPos As Long) As Long

Private Declare Function GetMenuString Lib "user32" Alias _
        "GetMenuStringA" (ByVal hMenu As Long, ByVal wIDItem _
        As Long, ByVal lpString As String, ByVal nMaxCount As _
        Long, ByVal wFlag As Long) As Long

Const GWL_WNDPROC = (-4&)
Const WM_SYSCOMMAND = &H112
Const WM_COMMAND = &H111
Const MF_BYCOMMAND = &H0&

Dim PrevWndProc&

Private Function WndProc(ByVal hwnd As Long, ByVal MSG As Long, _
                         ByVal wParam As Long, ByVal lParam As _
                         Long) As Long
  
  Dim mnuHandle&, Result&, Buffer$
  
    If MSG = WM_COMMAND Then
      mnuHandle = GetMenu(Form1.hwnd)
      
      If wParam >= &H2 And wParam <= &H5 Then
        mnuHandle = GetSubMenu(mnuHandle, 0&)
      Else
        mnuHandle = GetSubMenu(mnuHandle, 1&)
      End If
      
      Call SetMenuDefaultItem(mnuHandle, wParam, 0&)
      
      'Default String lesen, hier nur als Demo
      Result = GetMenuDefaultItem(mnuHandle, 0&, 0&)
      Buffer = Space$(128)
      Result = GetMenuString(mnuHandle, Result, Buffer, _
                             Len(Buffer), MF_BYCOMMAND)
      Form1.Caption = Left$(Buffer, Result)
    End If
  
    WndProc = CallWindowProc(PrevWndProc, hwnd, MSG, wParam, lParam)
End Function

Public Sub Init(hwnd&)
  PrevWndProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WndProc)
End Sub

Public Sub Terminate(hwnd&)
  Call SetWindowLong(hwnd, GWL_WNDPROC, PrevWndProc)
End Sub
'---------- Ende Modul "Module1" alias Module1.bas ----------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Menü "mnuMenü"
' Steuerelement: Menü "a" auf mnuMenü
' Steuerelement: Menü "b" auf mnuMenü
' Steuerelement: Menü "c" auf mnuMenü
' Steuerelement: Menü "d" auf mnuMenü
' Steuerelement: Menü "mnuExtras"
' Steuerelement: Menü "e" auf mnuExtras
' Steuerelement: Menü "f" auf mnuExtras
' Steuerelement: Menü "g" auf mnuExtras
' Steuerelement: Menü "h" auf mnuExtras
Option Explicit

Private Sub Form_Load()
  Call Init(Me.hwnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate(Me.hwnd)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 3 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von M.Schreck am 20.01.2005 um 09:42

Hallo

der Tip, um die MenüBar farbig zu gestalten ist gut , nur leider bleibt das selektierte Menü dennoch grau und das sieht sehr störend aus wenn alles andere Farbig ist. Wer hat eine Idee hierzu ?

Gruss

M.S.

Kommentar von HMS am 08.02.2004 um 12:10

Also soweit ich weiß gibt es in VB schon eine Methode um ein Menüitem fett erscheinen zu lassen (leider nur bei Popup-Menüs):

[Object].PopupMenu Menu As Object, Optional Flags, Optinal X, Optional Y, Optional DefaultMenu
Dieser letzte Parameter lässt ein Menüobjekt fett erscheinen.

Kommentar von m$2k am 20.09.2002 um 11:15

Im systemmenü ist der punkt "Maximieren" fett gedruckt. Ich kann den Funktionsaufruf aber nirgends im Code finden. Kann mir bitte jemand helfen, der peilt wie des geht?