Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0133: System-Menü manipulieren

 von 

Beschreibung 

Es folgt eine kleine Reihe von Beispielen rund um Menüs. VB selbst verfügt ja über einen recht komfortablen Menü-Editor. Dabei lassen sich aber alle Fuktionen und darüber hinaus noch zusätzliche, auch mit APIs realisieren. Zur Einführung hier am Beispiel des Systemmenüs demonstriert.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

AppendMenuA (AppendMenu), CallWindowProcA (CallWindowProc), GetSystemMenu, InsertMenuA (InsertMenu), RemoveMenu, SetWindowLongA (SetWindowLong)

Download:

Download des Beispielprojektes [2,69 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Beschriftungsfeld "Label1"
Option Explicit

Private Sub Form_Load()
  Call Init(Me.hwnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate(Me.hwnd)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit
                      
Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hwnd As Long, ByVal MSG As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
               
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Private Declare Function InsertMenu Lib "user32" Alias _
        "InsertMenuA" (ByVal hMenu As Long, ByVal nPosition _
        As Long, ByVal wFlags As Long, ByVal wIDNewItem As _
        Long, ByVal lpNewItem As Any) As Long
        
Private Declare Function RemoveMenu Lib "user32" (ByVal _
        hMenu As Long, ByVal nPosition As Long, ByVal wFlags _
        As Long) As Long

Private Declare Function GetSystemMenu Lib "user32" (ByVal _
        hwnd As Long, ByVal bRevert As Long) As Long
        
Private Declare Function AppendMenu Lib "user32" Alias _
        "AppendMenuA" (ByVal hMenu As Long, ByVal wFlags As _
        Long, ByVal wIDNewItem As Long, ByVal lpNewItem As _
        String) As Long

Const MF_STRING = &H0&
Const MF_SEPARATOR = &H800&
Const MF_BYPOSITION = &H400&

Const GWL_WNDPROC = (-4&)
Const WM_SYSCOMMAND = &H112

Dim PrevWndProc&, mnuHandle&

Private Function WndProc(ByVal hwnd As Long, ByVal MSG _
                         As Long, ByVal wParam As Long, _
                         ByVal lParam As Long) As Long
  Dim Result&
  
    If MSG = WM_SYSCOMMAND Then
      Select Case wParam
        Case &H200:  Form1.Caption = "Befehl 1"
        Case &H201:  Form1.Caption = "Befehl 2"
        Case &H202:  Form1.Caption = "Befehl 3"
         '... etc
      End Select
    End If
  
    WndProc = CallWindowProc(PrevWndProc, hwnd, MSG, wParam, lParam)
End Function

Public Sub Init(hwnd&)
  mnuHandle = GetSystemMenu(hwnd, False)
  
  'Strich ans Ende hängen
  Call AppendMenu(mnuHandle, MF_SEPARATOR, 0, "")
  
  '2 Befehle anhängen
  Call AppendMenu(mnuHandle, MF_STRING, &H200, "B&efehl 1")
  Call AppendMenu(mnuHandle, MF_STRING, &H201, "Be&fehl 2")
  
  'Einfügen eines neuen Eintrages an die 2. Position
  Call InsertMenu(mnuHandle, 2, MF_BYPOSITION, &H202, "Befehl 3")
  
  'Standardeintrag 'Wiederherstellen' entfernen
  Call RemoveMenu(mnuHandle, 0, MF_BYPOSITION)
  
  PrevWndProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WndProc)
End Sub

Public Sub Terminate(hwnd&)
  Call SetWindowLong(hwnd, GWL_WNDPROC, PrevWndProc)
End Sub
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 4 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Thomas Schmohl am 26.09.2005 um 20:28

Guten Tag,

ich suche schon eine ganze Weile einen Beispielsourcecode um Shell Extensions zu programmieren.
Mein Wunsch wäre es, übers Kontextmenü bei einem beliebigen Ordner dessen Unterordner anzuzeigen, ihn also zu expandieren.
Können Sie mir da weiterhelfen ? Vielen Dank !

MfG
Thomas S.

Kommentar von Willi am 10.09.2005 um 22:54

Hi,

nett, aber wie bekomme ich sowas in fremde Fenster ?
Hinein bekommen selbst ist kein Thema, FindWindow und ab gehts.

Aber das Ereignis bei Klick auf den Menüeintrag abfragen !!!???

Kommentar von am 06.01.2005 um 14:21

Hi

Wie kann ich einen Eintrag mit weiteren Untermenüs hinzufügen?

Kommentar von Frank Dzaebel am 12.02.2001 um 18:03

Unter NT4.0Sp5, VB6.0SP4 kommt es nach dem Start in der VB-IDE, rechte Maustaste im blauen Feld drücken, dann mit "X" schliessen, zu einem Absturz