Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0111: Position fremder Fenster bestimmen und ändern

VB 5/6-Tipp 0111: Position fremder Fenster bestimmen und ändern

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: FindWindowA (FindWindow), GetWindowRect, SetWindowPos, ShowWindow

Download: Download des Beispielprojektes [2,58 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Bildfeld-Steuerelement "Picture1"

Option Explicit

Private Declare Function SetWindowPos Lib "user32" (ByVal _
        hwnd As Long, ByVal hWndInsertAfter As Long, _
        ByVal x As Long, ByVal y As Long, ByVal cx As Long, _
        ByVal cy As Long, ByVal wFlags As Long) As Long

Private Declare Function ShowWindow Lib "user32" (ByVal _
        hwnd As Long, ByVal nCmdShow As Long) As Long

Private Declare Function GetWindowRect Lib "user32" (ByVal _
        hwnd As Long, lpRect As RECT) As Long

Private Declare Function FindWindow Lib "user32" Alias _
        "FindWindowA" (ByVal lpClassName As String, ByVal _
        lpWindowName As String) As Long

Const SWP_NOMOVE = &H2
Const SWP_NOSIZE = &H1
Const HWND_TOPMOST = -1

Const SW_MAXIMIZE = 3
Const SW_MINIMIZE = 6
Const SW_RESTORE = 9

Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

Dim XhWnd&

Private Sub Form_Load()
  Dim Result&
    Picture1.ScaleMode = vbPixels
    Picture1.Print "Hier die Maus drüber bewegen !"
  
    'NotePad starten
    Result = Shell("notepad.exe", vbNormalFocus)
  
    'Handle des Notepads auslesen
    XhWnd = FindWindow(vbNullString, "Unbenannt - Editor")
  
    'Eigenes Fenster nach oben setzen
    Result = SetWindowPos(Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, _
                          SWP_NOMOVE + SWP_NOSIZE)
End Sub

Private Sub Command1_Click()
  Call ShowWindow(XhWnd, SW_MINIMIZE)

End Sub

Private Sub Command2_Click()
  Call ShowWindow(XhWnd, SW_RESTORE)
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As _
                               Integer, x As Single, y As Single)
  Dim R As RECT, pX&, pY&
  
    'Neue Position berechnen
    pX = x * Screen.Width / Picture1.Width
    pY = y * Screen.Height / Picture1.Height
    
    'Neue Position Setzen
    Call SetWindowPos(XhWnd, 0, pX * 0.5, pY * 0.5, pX * 0.5 + _
                      pX * 0.25, pY * 0.5 + pY * 0.25, 0&)
    
    'Neue Position Auslesen und anzeigen
    Call GetWindowRect(XhWnd, R)
    Me.Caption = "[" & R.Left & "] [" & R.Top & "]"
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 3 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.