Startseite / Tipps / VB 5/6-Tipp 0069: Bildauschnitt mit API zoomen

VB 5/6-Tipp 0069: Bildauschnitt mit API zoomen

 von ActiveVB

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Timersteuerelement "Timer1"
' Steuerelement: Bildfeld-Steuerelement "Zoom"
' Steuerelement: Bildfeld-Steuerelement "Source"
' Steuerelement: Schaltfläche "Command1"

Option Explicit

Private Declare Function StretchBlt Lib "gdi32" _
        (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, _
        ByVal nWidth As Long, ByVal nHeight As Long, _
        ByVal hSrcDC As Long, ByVal xSrc As Long, _
        ByVal ySrc As Long, ByVal nSrcWidth As Long, _
        ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long
        
Private Declare Function SetStretchBltMode Lib "gdi32" _
        (ByVal hdc As Long, ByVal nStretchMode As Long) As Long
    
Const SRCCOPY = &HCC0020
Const DELETESCANS = 3

Dim Wert%, Schritt%

Private Sub Form_Load()
  Wert = 90
  Schritt = 5
End Sub

Private Sub Command1_Click()
  Timer1.Enabled = True
End Sub

Private Sub Command2_Click()
  Unload Me
End Sub

Private Sub Timer1_Timer()
  Call ZoomSub(Wert, Zoom)
  
  If Wert >= 200 Then Schritt = -Schritt
  If Wert <= 10 Then Schritt = -Schritt
  
  If Wert < 50 Then Schritt = Sgn(Schritt) * 2
  If Wert >= 50 Then Schritt = Sgn(Schritt) * 5
  
  Wert = Wert + Schritt
End Sub

Private Sub ZoomSub(ByVal Prozent, Bild As PictureBox)
  Dim dx1&, dy1&, dx2&, dy2&, tx&, ty&, SHdc&, ZHdc&

    tx = Screen.TwipsPerPixelX
    ty = Screen.TwipsPerPixelY
    
    dx1 = Source.Width / tx
    dy1 = Source.Height / ty
    
    dx2 = dx1 * Prozent / 100
    dy2 = dy1 * Prozent / 100
    
    ZHdc = Zoom.hdc
    SHdc = Source.hdc
    Zoom.AutoRedraw = False
    
    Call SetStretchBltMode(ZHdc, DELETESCANS)
    StretchBlt ZHdc, 0, 0, dx2, dy2, _
               SHdc, 0, 0, dx1, dy1, SRCCOPY
    Zoom.Refresh
    Zoom.AutoRedraw = True
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 4 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Const STRETCH_ANDSCANS = 1
Const STRETCH_ORSCANS = 2
Const DELETESCANS = 3
Const STRETCH_HALFTONE = 4