Startseite / Tipps / VB 5/6-Tipp 0023: Dynamische IP-Adresse auslesen, DNS nutzen

VB 5/6-Tipp 0023: Dynamische IP-Adresse auslesen, DNS nutzen

 von ActiveVB

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias FORM1.FRM  ---------
' Steuerelement: Schaltfläche "Command6"
' Steuerelement: Rahmensteuerelement "Frame2"
' Steuerelement: Timersteuerelement "Timer1" auf Frame2
' Steuerelement: Schaltfläche "Command7" auf Frame2
' Steuerelement: Schaltfläche "Command5" auf Frame2
' Steuerelement: Listen-Steuerelement "List1" auf Frame2
' Steuerelement: Textfeld "Text5" auf Frame2
' Steuerelement: Schaltfläche "Command1" auf Frame2
' Steuerelement: Schaltfläche "Command2" auf Frame2
' Steuerelement: Rahmensteuerelement "Frame1"
' Steuerelement: Textfeld "Text4" auf Frame1
' Steuerelement: Textfeld "Text3" auf Frame1
' Steuerelement: Schaltfläche "Command3" auf Frame1
' Steuerelement: Schaltfläche "Command4" auf Frame1
' Steuerelement: Textfeld "Text1" auf Frame1
' Steuerelement: Textfeld "Text2" auf Frame1
' Steuerelement: Beschriftungsfeld "Label2" auf Frame1
' Steuerelement: Beschriftungsfeld "Label1" auf Frame1
' Steuerelement: Beschriftungsfeld "Label3"

Option Explicit

Private Declare Function WSAGetLastError Lib "WSOCK32.DLL" () _
        As Long
        
Private Declare Function WSAStartup Lib "WSOCK32.DLL" (ByVal _
        wVersionRequired As Long, lpWSAData As WinSocketDataType) _
        As Long
        
Private Declare Function WSACleanup Lib "WSOCK32.DLL" () _
        As Long
        
Private Declare Function gethostname Lib "WSOCK32.DLL" (ByVal _
        HostName As String, ByVal HostLen As Integer) As Long
        
Private Declare Function gethostbyname Lib "WSOCK32.DLL" _
        (ByVal HostName As String) As Long
        
Private Declare Function gethostbyaddr Lib "WSOCK32.DLL" _
        (ByVal addr As String, ByVal laenge As Integer, ByVal typ As Integer) As Long
        
Private Declare Sub RtlMoveMemory Lib "kernel32" (hpvDest As _
        Any, ByVal hpvSource As Long, ByVal cbCopy As Long)

Const WS_VERSION_REQD As Long = &H101&

Const SOCKET_ERROR  As Long = -1
Const WSADescription_Len As Long = 256
Const WSASYS_Status_Len As Long = 128

Private Type HostDeType
    hName As Long
    hAliases As Long
    hAddrType As Integer
    hLength As Integer
    hAddrList As Long
End Type

Private Type WinSocketDataType
    wversion As Integer
    wHighVersion As Integer
    szDescription(0 To WSADescription_Len) As Byte
    szSystemStatus(0 To WSASYS_Status_Len) As Byte
    iMaxSockets As Integer
    iMaxUdpDg As Integer
    lpszVendorInfo As Long
End Type


'### Der folgende Abschnitt dient nur dazu, um festzustellen
'    ob eine Online-Verbindung besteht bzw. um diese herzu-
'    stellen und wieder abzubrechen.
'    Sie können diesen Block bei Verzicht dieser Funktionen
'    getrost löschen

Private Declare Function RasEnumConnections Lib "RasApi32.DLL" _
        Alias "RasEnumConnectionsA" (lpRasCon As Any, lpcb As _
        Long, lpcConnections As Long) As Long
        
Private Declare Function RasGetConnectStatus Lib "RasApi32.DLL" _
        Alias "RasGetConnectStatusA" (ByVal hRasCon As Long, _
        lpStatus As Any) As Long

Private Declare Function RasEnumEntries Lib "RasApi32.DLL" _
        Alias "RasEnumEntriesA" (ByVal reserved As String, ByVal _
        lpszPhonebook As String, lprasentryname As Long, lpcb As Long, _
        lpcEntries As Long) As Long
        
Private Declare Function RasHangUp Lib "RasApi32.DLL" _
        Alias "RasHangUpA" (ByVal hRasConn As Long) As Long

Const RAS_MaxEntryName As Long = 256&
Const RAS_MaxDeviceType As Long = 16&
Const RAS_MaxDeviceName As Long = 32&

Private Type RASType
    dwSize As Long
    hRasCon As Long
    szEntryName(RAS_MaxEntryName) As Byte
    szDeviceType(RAS_MaxDeviceType) As Byte
    szDeviceName(RAS_MaxDeviceName) As Byte
End Type

Private Type RASStatusType
    dwSize As Long
    RasConnState As Long
    dwError As Long
    szDeviceType(RAS_MaxDeviceType) As Byte
    szDeviceName(RAS_MaxDeviceName) As Byte
End Type

Private Type RASENTRYNAME95
    dwSize As Long
    szEntryName(RAS_MaxEntryName) As Byte
End Type

Dim DFUEName As String

Private Function DFUEStatus() As Boolean
    Dim RAS(255) As RASType, RASStatus As RASStatusType
    Dim lg As Long, lpcon As Long, Result As Long

    RAS(0).dwSize = 412
    lg = 256 * RAS(0).dwSize
    Result = RasEnumConnections(RAS(0), lg, lpcon)
    
    If lpcon = 0 Then
        DFUEStatus = False
        Label3.Caption = "Offline"
    Else
        RASStatus.dwSize = 160
        Result = RasGetConnectStatus(RAS(0).hRasCon, RASStatus)
        If RASStatus.RasConnState = &H2000 Then
            DFUEStatus = True
            Label3.Caption = "Online"
        Else
            DFUEStatus = False
            Label3.Caption = "Einwahl oder Trennen der Verbindung"
        End If
    End If
End Function

Private Function Online() As Boolean
    Dim Test As Boolean
    
    Test = DFUEStatus
    If Test = False Then Call MsgBox _
        ("Keine Online Verbindung vorhanden! Bitte einwählen!")
    
    Online = Test
End Function

Private Function GetDFUE() As String
    Dim s As Long, ln As Long
    Dim i As Integer
    Dim r(255) As RASENTRYNAME95
    
    r(0).dwSize = 264
    s = 256 * r(0).dwSize
    Call RasEnumEntries(vbNullString, vbNullString, VarPtr(r(0)), s, ln)
    DFUEName = StrConv(r(i).szEntryName(), vbUnicode)
    DFUEName = Left$(DFUEName, InStr(DFUEName, vbNullChar) - 1)
    Shell "rundll32.exe rnaui.dll,RnaDial " & DFUEName
    Shell "rundll32.exe rnaui.dll,RnaDial " & DFUEName
End Function

Private Sub HangUp(ByVal Verbindung$)
    Dim s As Long, l As Long, ln As Long
    Dim rec As Long
    Dim aa As String
    ReDim r(255) As RASType

    r(0).dwSize = 412
    s = 256 * r(0).dwSize
    l = RasEnumConnections(r(0), s, ln)
    
    For l = 0 To ln - 1
        aa = StrConv(r(l).szEntryName(), vbUnicode)
        aa = Left$(aa, InStr(aa, Chr$(0)) - 1)
        If aa = Verbindung Then rec = RasHangUp(r(l).hRasCon)
    Next l
End Sub

Private Sub Form_Load()
    Command1.Caption = "Eigene Adresse ermitteln"
    Command2.Caption = "Dynamische IP-Adressen"
    Command3.Caption = "IP->Name"
    Command4.Caption = "Name->Ip"
    Command5.Caption = "Einwählen"
    Command6.Caption = "Beenden"
    Command7.Caption = "Auflegen"

    Timer1.Interval = 200
    Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
    DFUEStatus
End Sub

Private Sub Command5_Click()
    Call GetDFUE
End Sub
Private Sub Command7_Click()
    If Len(DFUEName) > 0 Then Call HangUp(DFUEName)
End Sub
'### Ende des DFUE-Pfrüfungs Abschnitts


Private Sub Command1_Click()
    '### Eigene Adresse ermitteln
    InitSockets
    Text5.Text = MyHostName()
    CleanSockets
End Sub

Private Sub Command2_Click()
    '### Eigene IP-Adressen abfragen
    '    Diese Routine kann unteranderem dazu benutzt werden,
    '    dynamische durch einen Provider zugewiesene IP-Adressen
    '    auszulesen.
    '    Da hier alle eigenen IP ausgelesen werden müssen die statio-
    '    nären [Localhost (127.0.0.1), Netzwerk (192.168.xxx.xxx)]
    '    eleminiert werden. Entfernen Sie dann aber auch folgende
    '    Steuerelemente aus dem Form:
    '       Timer1
    '       Label3
    '       Command5
    '       Command7
 
    Dim X As Integer
    Dim IP As String, DNS As String, HOST As String
  
    If Not Online Then Exit Sub
    
    MousePointer = vbHourglass
    Call InitSockets
    HOST = MyHostName
    List1.Clear
     
    Do
        IP = HostByName(HOST, X)
        If Len(IP) = 0 Then Exit Do
          
        DNS = HostByAddress(IP)
        List1.AddItem "DNS: " & DNS & "  " & "IP: " & IP
        X = X + 1
    Loop
     
    Call CleanSockets
    MousePointer = vbDefault
End Sub

Private Sub Command3_Click()
    Dim aa As String
    '### DNS-Abfrage nach Domäne (gibt IP zurück)
    
    If Not Online Then Exit Sub
    
    MousePointer = vbHourglass
    Call InitSockets
    aa = HostByAddress(Text1.Text)
    If Len(aa) = 0 Then Call MsgBox("Nicht gefunden")
    Text4.Text = aa
    CleanSockets
    MousePointer = vbDefault
End Sub

Private Sub Command4_Click()
    Dim aa As String
    
    '### DNS-Abfrage nach IP (gibt Domäne zurück)
    If Not Online Then Exit Sub
    
    MousePointer = vbHourglass
    InitSockets
    aa = HostByName$(Text2.Text)
    If Len(aa) = 0 Then Call MsgBox("Nicht gefunden")
    Text3.Text = aa
    CleanSockets
    MousePointer = vbDefault
End Sub

Private Sub Command6_Click()
    Unload Me
End Sub

Private Function HostByAddress(ByVal Addresse$) As String
    Dim X As Integer
    Dim HostDeAddress As Long
    Dim aa As String, BB As String * 5
    Dim HOST As HostDeType
  
    aa = Chr$(Val(NextChar(Addresse, ".")))
    aa = aa + Chr$(Val(NextChar(Addresse, ".")))
    aa = aa + Chr$(Val(NextChar(Addresse, ".")))
    aa = aa + Chr$(Val(Addresse))
    
    HostDeAddress = gethostbyaddr(aa, Len(aa), 2)
    If HostDeAddress = 0 Then
        HostByAddress = ""
        Exit Function
    End If
    
    Call RtlMoveMemory(HOST, HostDeAddress, LenB(HOST))
 
    aa = ""
    X = 0
    Do
       Call RtlMoveMemory(ByVal BB, HOST.hName + X, 1)
       If Left$(BB, 1) = Chr$(0) Then Exit Do
       aa = aa + Left$(BB, 1)
       X = X + 1
    Loop
    
    HostByAddress = aa
End Function

Private Function HostByName(Name As String, Optional X As Integer = 0) As String
    Dim MemIp() As Byte
    Dim Y As Integer
    Dim HostDeAddress As Long, HostIp As Long
    Dim IpAddress As String
    Dim HOST As HostDeType
  
    HostDeAddress = gethostbyname(Name)
    If HostDeAddress = 0 Then
        HostByName = ""
        Exit Function
    End If
    
    Call RtlMoveMemory(HOST, HostDeAddress, LenB(HOST))
    
    For Y = 0 To X
        Call RtlMoveMemory(HostIp, HOST.hAddrList + 4 * Y, 4)
        If HostIp = 0 Then
            HostByName = ""
            Exit Function
        End If
    Next Y
    
    ReDim MemIp(1 To HOST.hLength)
    Call RtlMoveMemory(MemIp(1), HostIp, HOST.hLength)
    
    IpAddress = ""
    
    For Y = 1 To HOST.hLength
        IpAddress = IpAddress & MemIp(Y) & "."
    Next Y
    
    IpAddress = Left$(IpAddress, Len(IpAddress) - 1)
    HostByName = IpAddress
End Function

Private Function MyHostName() As String
    Dim HostName As String * 256
    
    If gethostname(HostName, 256) = SOCKET_ERROR Then
        MsgBox "Windows Sockets error " & Str(WSAGetLastError())
        Exit Function
    Else
        MyHostName = NextChar(Trim$(HostName), Chr$(0))
    End If
End Function

Private Sub InitSockets()
    Dim Result As Integer
    Dim LoBy As Integer, HiBy As Integer
    Dim SocketData As WinSocketDataType
    
    Result = WSAStartup(WS_VERSION_REQD, SocketData)
    If Result <> 0 Then
        Call MsgBox("'winsock.dll' antwortet nicht!")
        End
    End If
End Sub

Private Sub CleanSockets()
    Dim Result As Long
    
    Result = WSACleanup()
    If Result <> 0 Then
        Call MsgBox("Socket Error " & Trim$(Str$(Result)) & _
                " in Prozedur 'CleanSockets' aufgetreten !")
        End
    End If
End Sub

Private Function NextChar(Text$, Char$) As String
    Dim POS As Integer
    
    POS = InStr(1, Text, Char)
    If POS = 0 Then
        NextChar = Text
        Text = ""
    Else
        NextChar = Left$(Text, POS - 1)
        Text = Mid$(Text, POS + Len(Char))
    End If
End Function
'---------- Ende Formular "Form1" alias FORM1.FRM  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 15 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.