Startseite / Tipps / VB 5/6-Tipp 0012: Verfügbare Laufwerke, einschl. der Netzlaufwerke erkennen

VB 5/6-Tipp 0012: Verfügbare Laufwerke, einschl. der Netzlaufwerke erkennen

 von ActiveVB

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Listen-Steuerelement "List1"

Option Explicit

'Deklaration: Globale Form API-Konstanten
Private Const DRIVE_CDROM As Long = 5
Private Const DRIVE_FIXED As Long = 3
Private Const DRIVE_RAMDISK As Long = 6
Private Const DRIVE_REMOTE As Long = 4
Private Const DRIVE_REMOVABLE As Long = 2

'Deklaration: Globale Form API-Funktionen
Private Declare Function GetDriveType Lib "Kernel32" Alias "GetDriveTypeA" ( _
    ByVal nDrive As String) As Long

Private Declare Function GetLogicalDriveStrings Lib "Kernel32" _
    Alias "GetLogicalDriveStringsA" (ByVal nBufferLength As Long, _
    ByVal lpBuffer As String) As Long

Private Sub Command1_Click()
    'Deklaration: Lokale Prozedur-Variablen
    Dim lngErgebnis As Long
    Dim lngPuffer As Long
    Dim lngTyp As Long
    Dim x As Long

    Dim strBezeichnung As String
    Dim strLaufwerk As String
    Dim strLaufwerke As String
    Dim strPuffer As String

    List1.Clear

    'Speicherplatz reservieren
    lngPuffer = 64
    strPuffer = Space$(lngPuffer)

    'Laufwerksbuchstaben ermitteln
    lngErgebnis = GetLogicalDriveStrings(lngPuffer, strPuffer)
    strLaufwerke = Left$(strPuffer, lngErgebnis)

    Do While x < Len(strPuffer)
        x = InStr(strPuffer, vbNullChar)

        If x <> 0 Then
            strLaufwerk = Left$(strPuffer, x)
            strPuffer = Mid$(strPuffer, x + 1, Len(strPuffer))

            'Laufwerkstyp ermitteln
            lngTyp = GetDriveType(strLaufwerk)
            If lngTyp <> 1 Then
                Select Case lngTyp
                    Case DRIVE_CDROM
                        strBezeichnung = "CD-ROM"
                    Case DRIVE_FIXED
                        strBezeichnung = "Festplatte"
                    Case DRIVE_RAMDISK
                        strBezeichnung = "RAM-Disk"
                    Case DRIVE_REMOTE
                        strBezeichnung = "Netzlaufwerk"
                    Case DRIVE_REMOVABLE
                        strBezeichnung = "Wechseldatenträger"
                End Select

                'Laufwerkstyp und -buchstaben ausgeben
                strLaufwerk = UCase(Mid$(strLaufwerk, 1, 2))
                List1.AddItem strLaufwerk & " " & strBezeichnung
            End If
        Else
            Exit Do
        End If
    Loop
End Sub

Private Sub Form_Load()
    'Control-Eigenschaften initialisieren
    Command1.Caption = "Laufwerke suchen"
End Sub


'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

For i = 0 To Drive1.ListCount - 1
    List1.AddItem Drive1.List(i)
Next i