Outlookdaten auslesen

Voraussetzungen  

Bevor Outlook in das eigene Programm integriert werden kann, muß folgende Objektlibrary eingebunden werden:

• Microsoft Outlook 8.0 Object Library

Erklärung anhand des Beispielprojekts  

Option Explicit

' Nachfolgend werden zwei komplette Objekte
' für die Outlook.Application angelegt; diese
' Vorgehensweise ist notwendig, da das Programm
' Kontakte und eMails parallel öffnen können
' soll. In diesem Tutorial ist eigentlich nur
' die ständige Verwendung des Mailobjekts (alle
' Objekte, die mit "Mobj" beginnen, notwendig.
' Allerdings wird das Kontaktobjekt nicht geschlossen,
' da das Listing einfach um die eigenen Wünsche
' erweiterbar sein soll.

Dim KobjOutlook As Outlook.Application
' Outlook wird als Objekt festgelegt
' Bitte beachten: unter Verweise "Projekt / Verweise"
' muß "Microsoft Outlook 8.0 Object Lib." angebunden
' sein

Dim KobjNS As NameSpace
' mit den Namespaces wird der aktuelle Arbeitsbereich
' von Outlook festgelegt und stellt Methoden zur
' An- und Abmeldung in Outlook bereit.

Dim KobjMF As MAPIFolder
' der MAPI-Folder legt den Ordner fest (z. B. Kontakte)

Dim KobjIt As Items
' die Items sind die einzelnen Einträge

Dim MobjOutlook As Outlook.Application
' Outlook wird als Objekt festgelegt
' Bitte beachten: unter Verweise "Projekt / Verweise"
' muß "Microsoft Outlook 8.0 Object Lib." angebunden
' sein

Dim MobjNS As NameSpace
' mit den Namespaces wird der aktuelle Arbeitsbereich
' von Outlook festgelegt und stellt Methoden zur
' An- und Abmeldung in Outlook bereit.

Dim MobjMF As MAPIFolder
' der MAPI-Folder legt den Ordner fest (z. B. Kontakte)

Dim MobjIt As Items
' die Items sind die einzelnen Einträge

Dim zaehler As Integer
' einfache Integervariable zur Füllung der Listboxen

Dim AktuellerUserKontakte As String
' zur Speicherung des Usernamens - vom Profil abhängig

Dim AktuellerUserMails As String
' zur Speicherung des Usernamens - vom Profil abhängig

Private Sub Command1_Click()
  Call kontakte_lesen
End Sub

Private Sub Command2_Click()
  Call mailtopics_lesen
End Sub

Private Sub Command3_Click()
  Call Maillist_Click
End Sub

Private Sub form_load()
  MsgBox "Willkommen im Outlook-Reader 1.0", , _
         "Outlook-Reader 1.0"

  Command3.Visible = False
  ' Button zum Anzeigen der einzelnen Mail deaktivieren
End Sub

Private Sub form_Unload(Cancel As Integer)
  ' alle Objekte abschließen
  Set KobjOutlook = Nothing
  Set KobjNS = Nothing
  Set KobjIt = Nothing
  Set KobjMF = Nothing

  Set MobjOutlook = Nothing
  Set MobjNS = Nothing
  Set MobjIt = Nothing
  Set MobjMF = Nothing
End Sub

Sub kontakte_lesen()
  MousePointer = vbHourglass
  ' das erste Auslesen kann einen ganzen Moment dauern

  Set KobjOutlook = New Outlook.Application
  ' Outlook initialisieren

  Set KobjNS = KobjOutlook.GetNamespace("MAPI")
  ' Namespace initialisieren

  AktuellerUserKontakte = KobjNS.CurrentUser
  Label3 = "aktueller User: " & AktuellerUserKontakte

  Set KobjMF = KobjNS.GetDefaultFolder(olFolderContacts)
  ' Ordner (Folder) setzen / in diesem Fall Contacts

  Set KobjIt = KobjMF.Items
  ' die Items initialisieren

  KobjIt.Sort "[Lastname]", False
  ' Einträge nach dem Nachnamen sortieren lassen

  ' Alle Items in die Listbox schreiben (Zuname & Vorname)
  For zaehler = 1 To KobjIt.Count
    Kontaktlist.AddItem KobjIt(zaehler).LastName & ", " _
                        & KobjIt(zaehler).FirstName
    ' über das Objekt KobjIt(Itemnummer)
    ' kann das einzelne Objekt aufgerufen werden;
    ' die jeweilige Property kann mit .Property (z. B.
    ' .Lastname) aufgerufen werden
  Next zaehler

  MousePointer = vbDefault
  ' Mousepointer wieder "normal" einstellen
End Sub

Private Sub mailtopics_lesen()
  MousePointer = vbHourglass
  ' das erste Auslesen kann einen ganzen Moment dauern

  Set MobjOutlook = New Outlook.Application
  ' Outlook initialisieren

  Set MobjNS = MobjOutlook.GetNamespace("MAPI")
  ' Namespace initialisieren

  Set MobjMF = MobjNS.GetDefaultFolder(olFolderInbox)
  ' Ordner (Folder) setzen / in diesem Fall Contacts

  AktuellerUserMails = MobjNS.CurrentUser
  Label4 = "aktueller User: " & AktuellerUserMails

  Set MobjIt = MobjMF.Items
  ' die Items initialisieren

  MobjIt.Sort "[ReceivedTime]", True
  ' Einträge nach dem Eingangsdatum und der -zeit
  ' sortieren lassen; True bedeutet absteigend

  ' Alle Items in die Listbox schreiben (Betreffzeile)
  For zaehler = 1 To MobjIt.Count
    Maillist.AddItem MobjIt(zaehler).Subject
    ' über das Objekt MobjIt(Itemnummer)
    ' kann das einzelne Objekt aufgerufen werden;
    ' die jeweilige Property kann mit .Property (z. B.
    ' .Subject) aufgerufen werden
  Next zaehler

  If Maillist.ListCount > 0 Then Command3.Visible = True
  ' wenn eMails vorhanden sind, wird der "Anzeigen"-
  ' Button aktiviert

  MousePointer = vbDefault
  ' Mousepointer wieder "normal" einstellen
End Sub

Private Sub Maillist_Click()
  If Maillist.ListIndex >= 0 Then
  ' wenn ein Item aus der Listbox gewählt ist, dann
  ' wird die einzelne Mail angezeigt

  Form2.Label6 = MobjIt(Form1.Maillist.ListIndex + _
                        1).CreationTime
  ' das Erstellungsdatum und die -Zeit wird dargestellt
  Form2.Text1 = MobjIt(Form1.Maillist.ListIndex + 1).SenderName
  ' der Name des Absenders wird eingefügt
  Form2.Text2 = MobjIt(Form1.Maillist.ListIndex + 1).CC
  ' die weiteren Empfänger (CC) werden eingefügt
  Form2.Text3 = MobjIt(Form1.Maillist.ListIndex + 1).Subject
  ' das Subject (der Betreff) wird eingefügt
  Form2.Text4 = MobjIt(Form1.Maillist.ListIndex + 1).Body
  ' der Mailinhalt wird eingefügt
  If MobjIt(Form1.Maillist.ListIndex + 1).Attachments.Count > 0 Then
  ' es wird auf Attachments geprüft
    Form2.Text5 = ""
    For zaehler = 1 To MobjIt(Form1.Maillist.ListIndex + _
                              1).Attachments.Count
      Form2.Text5 = Form2.Text5 + "<" + _
                    MobjIt(Form1.Maillist.ListIndex + _
                    1).Attachments.Item(zaehler) + ">"
      ' die Namen der Attachments werden
      ' eingefügt
    Next zaehler
  Else
    Form2.Text5 = "Keine Attachments"
    ' keine Attachment da
  End If
  Form2.Show

  End If
End Sub

Listing 1

Projekt zum Download [4100 Bytes]

Eigenschaften (Properties)  

Eigenschaften der einzelnen Items:

• Kontakte:
  • CustomerID
  • Title
  • Firstname
  • Middlename
  • LastName
  • Suffix
  • FullName
  • Jobtitle
  • Categories
  • Nickname
  • Profession
  • Gender
  • BusinessAdressStreet
  • BusinessAdressCity
  • BusinessAdressState
  • BusinessAdressPostalCode
  • BusinessAdressCountry
  • BusinessAdress
  • HomeAdressStreet
  • HomeAdressCity
  • HomeAdressState
  • HomeAdressPostalCode
  • HomeAdressCountry
  • HomeAdress
  • BusinessTelephoneNumber
  • BusinessFaxNumber
  • HomeTelephoneNumber
  • HomeFaxNumber
  • EmailAddress1
  • EmailAddress2
  • MobileTelephoneNumber
  • AutoTelephoneNumber
  • ISDNNumber
• Mails
  • SenderName
  • CC
  • Subject
  • CreationsTime
  • Attachments.Count
  • Attachments.Item(Index)

Ihre Meinung  

Falls Sie Fragen zu diesem Tutorial haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.