Startseite / Tipps / VB.NET-Tipp 0042: Doppelte Einträge entfernen

VB.NET-Tipp 0042: Doppelte Einträge entfernen

 von Spatzenkanonier

' Dieser Quellcode stammt von http://www.activevb.de
' und kann frei verwendet werden. Für eventuelle Schäden
' wird nicht gehaftet.

' Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
' Ansonsten viel Spaß und Erfolg mit diesem Source!

' Projektversion:   Visual Studio 2005
' Option Strict:    An
' Option Explicit:  An
'
' Referenzen: 
'  - System
'  - System.Data
'  - System.Drawing
'  - System.Windows.Forms
'  - System.Xml
'
' Imports: 
'  - Microsoft.VisualBasic
'  - System
'  - System.Collections
'  - System.Collections.Generic
'  - System.Data
'  - System.Diagnostics
'  - System.Drawing
'  - System.Windows.Forms
'

' ##############################################################################
' ################################# Form1.vb ###################################
' ##############################################################################
Imports System.ComponentModel

Public Class Form1

    ' Dient der Wiederherstellung des Anfangs-Zustandes
    Private _Template(2000) As Integer

    ' Die zur Anzeige gebrachten Daten
    Private _UnderlyingData As New List(Of Integer)

    ' _DataSource wird als Wrapper um _UnderlyingData initialisiert. Die 
    '  Bindinglist meldet direkte Änderungen sofort an die gebundenen Controls. 
    '  Änderungen an _UnderlyingData dagegen werden nicht "bemerkt". Daher ist 
    '  in _UnderlyingData eine viel schnellere Datenverarbeitung möglich, weil 
    '  nicht bei jeder Veränderung die angebunden Controls benachrichtigt werden.
    Private _DataSource As New BindingList(Of Integer)(_UnderlyingData)

    Private Sub Form1_Load(ByVal sender As Object, _
                           ByVal e As EventArgs) Handles MyBase.Load
        Dim rnd As New Random()
        For i As Integer = 0 To _Template.Length - 1
            _Template(i) = rnd.Next(0, 300)
        Next
        _UnderlyingData.AddRange(_Template)
        ListBox1.DataSource = _DataSource
    End Sub

    Private Sub Button_Click(ByVal sender As Object, _
            ByVal e As EventArgs) Handles _
            btRestoreSource.Click, btRemoveDoubles.Click, btSort.Click
        Select Case True
            Case sender Is btRestoreSource
                _UnderlyingData.Clear()
                _UnderlyingData.AddRange(_Template)

            Case sender Is btRemoveDoubles
                RemoveDoubles(_UnderlyingData)

            Case sender Is btSort
                ' Sortieren der Items macht vorhandene Doppelungen sofort
                '  sichtbar
                _UnderlyingData.Sort()

        End Select
        _DataSource.ResetBindings() ' angebundene Controls benachrichtigen
    End Sub

    Public Sub RemoveDoubles(Of T)(ByVal lst As List(Of T))
        ' Der Algorithmus ist eigentlich ganz unnötig auf Geschwindigkeit 
        '  optimiert: Das hierauf folgende Zeichnen der Listbox wird ca. 
        '  500 - 1000 fach langsamer sein. (In VB2008 bietet übrigens die 
        '  Extension-Method "Linq.Enumerable.Distinct()" vergleichbare 
        '  Funktionalität.)
        Dim known As New Dictionary(Of T, Byte)
        Dim i As Integer = 0
        'erste Doppelung suchen
        For i = 0 To lst.Count - 1
            Dim itm As T = lst(i)
            If known.ContainsKey(itm) Then Exit For
            known.Add(itm, 0)
        Next
        ' Nach der ersten Doppelung wird der vorlaufende Zähler ii eingeführt, 
        '  und unbekannte Items werden an die Position des jetzt nachlaufenden 
        '  Zählers i kopiert
        For ii As Integer = i + 1 To lst.Count - 1
            Dim itm As T = lst(ii)
            If Not known.ContainsKey(itm) Then
                known.Add(itm, 0)
                lst(i) = itm
                i += 1
            End If
        Next
        lst.RemoveRange(i, lst.Count - i)
    End Sub

End Class

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 10 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

'Alle Einträge durchgehen
        For i1 = 0 To UBound(Entries1)
            'Flag setzen
            found = False
            
            'Alle bereits in die neue Liste eingefügten
            ' Einträge(durchgehen)
            For i2 = 0 To UB
                'Schon Initialisiert?
                If Not DidInit Then
                    'Wenn nicht, erst Initialisieren(später)
                    found = False
                    Exit For
                ElseIf Entries1(i1) = Entries2(i2) Then
                    'Eintrag in Liste gefunden
                    found = True
                    Exit For
                End If
            Next
            
            'Wurde Eintrag in Liste gefunden?
            If Not found Then
                'Wurde bereits Initialisierung durchgeführt?
                If Not DidInit Then
                    'Neue Liste auf erforderliche Größe setzen
                    ReDim Entries2(UBound(Entries1))
                    DidInit = True
                End If
                
                'In neue Liste einfügen
                Entries2(UB) = Entries1(i1)
                
                'Zähler hochsetzen. Enthält die Nummer des
                ' letzten Eintrags der neuen Liste.
                UB = UB + 1
            End If
        Next
        
        'Einmal zuviel erhöht
        UB = UB - 1
        'Restlichen Elemente abschneiden.
        ReDim Preserve Entries2(UB)
        
        'Liste leeren und mit neuer Liste neu füllen
        LBox.Items.Clear()
        For i1 = 0 To UB
            LBox.Items.Add(Entries2(i1))
        Next
    End Sub