Startseite / Tipps / VB 5/6-Tipp 0587: NewWindow-Event des Webbrowser-Steuerelements richtig nutzen

VB 5/6-Tipp 0587: NewWindow-Event des Webbrowser-Steuerelements richtig nutzen

 von Jonathan Haas

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'----------- Anfang Projektdatei minibrowser.vbp  -----------
' Die Komponente 'Microsoft Windows Common Controls 6.0 (SP6) (MsComCtl.ocx)' wird benötigt.
' Die Komponente 'Microsoft Internet Controls (SHDOCVW.dll)' wird benötigt.

'---- Anfang Formular "frmBrowser" alias frmBrowser.frm  ----
' Steuerelement: Toolbar "tbToolBar"
' Steuerelement: Webbrowsercontrol "brwWebBrowser"
' Steuerelement: Bildfeld-Steuerelement "picAddress"
' Steuerelement: Textfeld "txtaddress" auf picAddress
' Steuerelement: Beschriftungsfeld "lblAddress" auf picAddress
' Steuerelement: Bilderlistenelement "imlIcons"

Option Explicit


Private Sub brwWebBrowser_NewWindow2(ppDisp As Object, Cancel As Boolean)
'neues Formular laden
    Dim frmNew As frmBrowser
    Set frmNew = New frmBrowser
    
'neues Formular ein bischen verschieben
    frmNew.WindowState = vbNormal
    frmNew.Top = frmNew.Top + 1200
    frmNew.Left = frmNew.Left + 1200
    Set ppDisp = frmNew.brwWebBrowser.Object   'das hier ist der Trick
    frmNew.Show
End Sub



'Die folgenden Funktionen steuern allgemein den Browser und das Formular

Private Sub brwWebBrowser_NavigateComplete2(ByVal pDisp As Object, URL As Variant)
txtaddress.Text = brwWebBrowser.LocationURL
End Sub

Private Sub brwWebBrowser_TitleChange(ByVal Text As String)
Me.Caption = Text & " - Browser" 'Neue Beschriftung zuweisen
End Sub

Private Sub Form_Load()
brwWebBrowser.GoHome 'Am Anfang zur Startseite navigieren
End Sub


Private Sub txtAddress_KeyPress(KeyAscii As Integer)
    If KeyAscii = vbKeyReturn Then
    brwWebBrowser.Navigate txtaddress.Text
    End If
End Sub

Private Sub Form_Resize()
    txtaddress.Width = Me.ScaleWidth - 80
    brwWebBrowser.Width = Me.ScaleWidth - 100
    brwWebBrowser.Height = Me.ScaleHeight - (picAddress.Top + picAddress.Height) - 50
End Sub


Private Sub tbToolBar_ButtonClick(ByVal Button As Button)
'Die Toolbar verarbeiten
    Select Case Button.Key
        Case "Back"
            brwWebBrowser.GoBack
        Case "Forward"
            brwWebBrowser.GoForward
        Case "Refresh"
            brwWebBrowser.Refresh
        Case "Home"
            brwWebBrowser.GoHome
        Case "Search"
            brwWebBrowser.GoSearch
        Case "Stop"
            brwWebBrowser.Stop
    End Select
End Sub

'----- Ende Formular "frmBrowser" alias frmBrowser.frm  -----
'------------ Ende Projektdatei minibrowser.vbp  ------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 8 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Call brwWebBrowser.Move(50, 1215, Me.ScaleWidth - 100, Me.ScaleHeight - (picAddress.Top + picAddress.Height) - 50)