Startseite / Tipps / VB 5/6-Tipp 0269: Dateien Zippen & Entpacken mit der PKZIP25 Commandline

VB 5/6-Tipp 0269: Dateien Zippen & Entpacken mit der PKZIP25 Commandline

 von ActiveVB

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Dateiauswahlliste "File1"

Option Explicit

Private Declare Function WaitForSingleObject Lib "kernel32" _
        (ByVal hHandle As Long, ByVal dwMilliseconds As Long) _
        As Long

Private Declare Function CloseHandle Lib "kernel32" (ByVal _
        hObject As Long) As Long
   
Private Declare Function OpenProcess Lib "kernel32" (ByVal _
        dwDesiredAccess As Long, ByVal bInheritHandle As _
        Long, ByVal dwProcessId As Long) As Long
        
Const INFINITE = -1&
Const SYNCHRONIZE = &H100000

Dim PKZIP25_Path$
Dim Zip_File_Path$
Dim Zip_File_Name$

Private Sub Form_Load()
  PKZIP25_Path = App.Path & "\PKZIP25.EXE"
  Zip_File_Name = "Test.zip"
  Zip_File_Path = App.Path & "\ZipVerzeichnis"
  If Len(Dir(Zip_File_Path, vbDirectory)) = 0 Then
        MkDir Zip_File_Path
  End If
  
  File1.Path = Zip_File_Path
    
  If Dir$(PKZIP25_Path, vbNormal) = "" Then
    Call InitPKZIP25
  End If
    
  If Dir(Zip_File_Path & "\" & Zip_File_Name) <> "" Then
    Command1.Caption = "Dateien Entpacken"
  Else
    Command1.Caption = "Dateien Zippen"
  End If
End Sub

Private Sub Command1_Click()
  MousePointer = vbHourglass
  If Dir(Zip_File_Path & "\" & Zip_File_Name) <> "" Then
    Call UnZipFiles
    Command1.Caption = "Dateien Zippen"
  Else
    Call ZipFiles
    Command1.Caption = "Dateien Entpacken"
  End If
  MousePointer = vbDefault
End Sub

Private Sub ZipFiles()
  Dim OldDir$, hProcess&, Result&, Task&, l&, x&
  
    OldDir = CurDir()
    ChDrive Left$(Zip_File_Path, 2)
    ChDir Zip_File_Path
        
    Task = Shell(PKZIP25_Path & " -add " & _
                 Zip_File_Name & " *.*", vbHide)

    hProcess = OpenProcess(SYNCHRONIZE, False, Task)
    Result = WaitForSingleObject(hProcess, INFINITE)
    Result = CloseHandle(hProcess)

    If File1.ListCount <> 0 Then
      For x = 0 To File1.ListCount - 1
        If LCase(Right$(File1.List(x), 4)) <> ".zip" Then
          l = l + FileLen(File1.Path & "\" & File1.List(x))
          Kill File1.Path & "\" & File1.List(x)
        End If
      Next x
    End If
    
    File1.Refresh
    x = FileLen(Zip_File_Path & "\" & Zip_File_Name)
    Me.Caption = "Vorher: " & Int(l / 1024) & "kB  Nacher: " & _
                 Int(x / 1024) & "kB"
    
    ChDrive Left$(OldDir, 2)
    ChDir OldDir
End Sub

Private Sub UnZipFiles()
  Dim OldDir$, hProcess&, Result&, Task&, l&, x&, y&
  
    OldDir = CurDir()
    ChDrive Left$(Zip_File_Path, 2)
    ChDir Zip_File_Path

    Task = Shell(PKZIP25_Path & " -extract " & Zip_File_Name, _
                 vbHide)

    hProcess = OpenProcess(SYNCHRONIZE, False, Task)
    Result = WaitForSingleObject(hProcess, INFINITE)
    Result = CloseHandle(hProcess)

    If Dir(Zip_File_Path & "\" & Zip_File_Name) <> "" Then
      y = FileLen(Zip_File_Path & "\" & Zip_File_Name)
      Kill Zip_File_Path & "\" & Zip_File_Name
    End If
    File1.Refresh
    If File1.ListCount <> 0 Then
      For x = 0 To File1.ListCount - 1
        If LCase(Right$(File1.List(x), 4)) <> ".zip" Then
          l = l + FileLen(File1.Path & "\" & File1.List(x))
        End If
      Next x
    End If
    
    Me.Caption = "Vorher: " & Int(y / 1024) & "kB  Nacher: " & _
                 Int(l / 1024) & "kB"

    ChDrive Left$(OldDir, 2)
    ChDir OldDir
End Sub

'Die folgende Routine wird nach der ersten Extraktion von
'pk250c32.exe nicht mehr benötigt und kann daher entfernt
'werden
    
Private Sub InitPKZIP25()
  Dim hProcess&, Result&, Task&
       
    If Dir$(App.Path & "\pk250c32.exe", vbNormal) = "" Then
      MsgBox ("Die Datei " & Chr$(34) & "pk250c32.exe" & _
              Chr$(34) & " ist Nicht vorhanden!" & vbCrLf & _
              "Sie ist zwingend notwendig, daher wird der " & _
              "Vorgang abgebrochen!")
      End
    Else
      Task = Shell(App.Path & "\pk250c32.exe", vbHide)
      hProcess = OpenProcess(SYNCHRONIZE, False, Task)
      Result = WaitForSingleObject(hProcess, INFINITE)
      Result = CloseHandle(hProcess)
      Kill App.Path & "\pk250c32.exe"
    End If
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 20 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Task = Shell(PKZIP25_Path & " -extract " & Zip_File_Name, vbHide)

Task = Shell(PKZIP25_Path & " -extract """ & ZipFileName & """", vbHide)