Startseite / Tipps / VB 5/6-Tipp 0266: Verzeichnis mittels API auslesen

VB 5/6-Tipp 0266: Verzeichnis mittels API auslesen

 von Henrik Ilgen

' Dieser Quellcode stammt von http://www.activevb.de
' und kann frei verwendet werden. Für eventuelle Schäden
' wird nicht gehaftet.
' Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
' Ansonsten viel Spaß und Erfolg mit diesem Source!
' ------------- Anfang Projektdatei Project1.vbp -------------
' ------- Anfang Formular "frmMain" alias frmMain.frm  -------
' Steuerelement: Listen-Steuerelement "lstResults"
Option Explicit

Private Sub Form_Load()

    Dim FoundFiles As modAPI.SearchResult
    Dim FileName   As String
    Dim n          As Long
    
    If modAPI.GetFiles("C:\*.*", FoundFiles) Then
    
        Me.Caption = CStr(FoundFiles.FileCount) & " Dateien und " & CStr( _
            FoundFiles.FolderCount) & " Ordner gefunden."
            
        For n = 0 To FoundFiles.FolderCount - 1
        
            FileName = Left$(FoundFiles.Folders(n).cFileName, InStr(1, _
                FoundFiles.Folders(n).cFileName, vbNullChar) - 1)
                
            Call lstResults.AddItem("\" & FileName)
            
        Next n
        
        For n = 0 To FoundFiles.FileCount - 1
        
            FileName = Left$(FoundFiles.Files(n).cFileName, InStr(1, _
                FoundFiles.Files(n).cFileName, vbNullChar) - 1)
                
            Call lstResults.AddItem(FileName)
            
        Next n
        
    Else
    
        Me.Caption = "Suche ist fehlgeschlagen/Keine Suchergebnisse"
        
    End If
    
End Sub

' -------- Ende Formular "frmMain" alias frmMain.frm  --------
' ---------- Anfang Modul "modAPI" alias modAPI.bas ----------
Option Explicit

Private Declare Function FindFirstFile Lib "kernel32" _
                         Alias "FindFirstFileA" ( _
                         ByVal lpFileName As String, _
                         ByRef lpFindFileData As WIN32_FIND_DATA) As Long
                         
Private Declare Function FindNextFile Lib "kernel32" _
                         Alias "FindNextFileA" ( _
                         ByVal hFindFile As Long, _
                         ByRef lpFindFileData As WIN32_FIND_DATA) As Long
                         
Private Declare Function FindClose Lib "kernel32" ( _
                         ByVal hFindFile As Long) As Long
                         
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
Private Const INVALID_HANDLE_VALUE = -1
Private Const MAX_PATH = 260

Public Type FILETIME
    dwLowDateTime      As Long
    dwHighDateTime     As Long
End Type

Public Type WIN32_FIND_DATA
    dwFileAttributes   As Long
    ftCreationTime     As FILETIME
    ftLastAccessTime   As FILETIME
    ftLastWriteTime    As FILETIME
    nFileSizeHigh      As Long
    nFileSizeLow       As Long
    dwReserved0        As Long
    dwReserved1        As Long
    cFileName          As String * MAX_PATH
    cAlternate         As String * 14
End Type

Public Type SearchResult
    Folders()         As WIN32_FIND_DATA
    Files()           As WIN32_FIND_DATA
    FolderCount       As Long
    FileCount         As Long
End Type

Public Function GetFiles(ByVal SearchPattern As String, ByRef Result As _
    SearchResult) As Boolean
    
    Dim FileName      As String
    Dim FolderCount   As Long
    Dim FileCount     As Long
    Dim hSearch       As Long
    Dim FindData      As WIN32_FIND_DATA
    
    hSearch = FindFirstFile(SearchPattern, FindData)
    
    If hSearch = INVALID_HANDLE_VALUE Then
    
        ' Suche ist fehlgeschlagen (bspw. keine Suchergebnisse). False
        ' zurückgeben und Funktion verlassen.
        GetFiles = False
        
        Exit Function
        
    End If
    
    ReDim Result.Files(100)
    ReDim Result.Folders(100)
    
    Do
    
        If (FindData.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY) <> 0 Then
        
            ' Es handelt sich um einen Ordner
            Result.Folders(FolderCount) = FindData
            FolderCount = FolderCount + 1
            
            ' Muss zusätzlicher Platz geschaffen werden?
            If FolderCount > UBound(Result.Folders) Then
            
                ReDim Preserve Result.Folders(FolderCount + 100)
                
            End If
            
        Else
        
            ' Es handelt sich um eine Datei
            Result.Files(FileCount) = FindData
            FileCount = FileCount + 1
            
            ' Muss zusätzlicher Platz geschaffen werden?
            If FileCount > UBound(Result.Files) Then
            
                ReDim Preserve Result.Files(FileCount + 100)
                
            End If
        End If
        
    Loop While FindNextFile(hSearch, FindData) <> 0
    
    ' Such-Handle schließen
    Call FindClose(hSearch)
    
    If FolderCount > 0 Then
    
        ' Wenn Ordner gefunden wurden, Array zurechtschneiden
        ReDim Preserve Result.Folders(FolderCount - 1)
        
    Else
    
        ' Wenn keine Ordner gefunden wurden, Array löschen
        Erase Result.Folders
        
    End If
    
    If FileCount > 0 Then
    
        ' Wenn Dateien gefunden wurden, Array zurechtschneiden
        ReDim Preserve Result.Files(FileCount - 1)
        
    Else
    
        ' Wenn keine Dateien gefunden wurden, Array löschen
        Erase Result.Files
        
    End If
    
    ' Anzahl gefundener Ordner und Dateien setzen
    Result.FolderCount = FolderCount
    Result.FileCount = FileCount
    GetFiles = True
    
End Function

' ----------- Ende Modul "modAPI" alias modAPI.bas -----------
' -------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

If (File <> ".") And (File <> "..") Then
           List1.AddItem "." & File 'Verzeichnis
           Dirs = Dirs + 1
End If