VB 5/6-Tipp 0260: E-Mails im HTML-Format mit Attachments versenden

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Es muss ein Verweis auf 'SMTP Send Mail for VB6.0' gesetzt werden.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Rahmensteuerelement "Frame5"
' Steuerelement: Listen-Steuerelement "List2" auf Frame5
' Steuerelement: Bildfeld-Steuerelement "Picture1" auf Frame5
' Steuerelement: Beschriftungsfeld "Label3" auf Frame5
' Steuerelement: Rahmensteuerelement "Frame2"
' Steuerelement: Schaltfläche "Command4" auf Frame2
' Steuerelement: Festplattenauswahlliste "Drive1" auf Frame2
' Steuerelement: Dateiauswahlliste "File1" auf Frame2
' Steuerelement: Verzeichnisauswahlliste "Dir1" auf Frame2
' Steuerelement: Rahmensteuerelement "Frame1"
' Steuerelement: Textfeld "Text5" auf Frame1
' Steuerelement: Textfeld "Text4" auf Frame1
' Steuerelement: Kontrollkästchen-Steuerelement "Check2" auf Frame1
' Steuerelement: Optionsfeld-Steuerelement "Option1" (Index von 0 bis 1) auf Frame1
' Steuerelement: Textfeld "Text1" auf Frame1
' Steuerelement: Textfeld "Text2" auf Frame1
' Steuerelement: Textfeld "Text3" auf Frame1
' Steuerelement: Kontrollkästchen-Steuerelement "Check1" auf Frame1
' Steuerelement: Beschriftungsfeld "Label1" auf Frame1
' Steuerelement: Beschriftungsfeld "Label2" auf Frame1
' Steuerelement: Beschriftungsfeld "Label7" auf Frame1
' Steuerelement: Beschriftungsfeld "Label6" auf Frame1
' Steuerelement: Beschriftungsfeld "Label5" auf Frame1
' Steuerelement: Beschriftungsfeld "Label4" auf Frame1
' Steuerelement: Rahmensteuerelement "Frame3"
' Steuerelement: Listen-Steuerelement "List1" auf Frame3
' Steuerelement: Textfeld "Text6" auf Frame3
' Steuerelement: Textfeld "Text7" auf Frame3
' Steuerelement: Textfeld "Text10" auf Frame3
' Steuerelement: Textfeld "Text11" auf Frame3
' Steuerelement: Textfeld "Text9" auf Frame3
' Steuerelement: Textfeld "Text8" auf Frame3
' Steuerelement: Beschriftungsfeld "Label15" auf Frame3
' Steuerelement: Beschriftungsfeld "Label14" auf Frame3
' Steuerelement: Beschriftungsfeld "Label13" auf Frame3
' Steuerelement: Beschriftungsfeld "Label12" auf Frame3
' Steuerelement: Beschriftungsfeld "Label11" auf Frame3
' Steuerelement: Beschriftungsfeld "Label10" auf Frame3
' Steuerelement: Beschriftungsfeld "Label9" auf Frame3

Option Explicit

Private WithEvents SendMail As vbSendMail.clsSendMail

Dim Att As String
Dim AuthLogin As Boolean
Dim HTML As Boolean
Dim MyEncodeType As ENCODE_METHOD

Private Sub Form_Load()
  Set SendMail = New clsSendMail
  Call ProgressBar(0, 0, 100)
  Call RetrieveSavedValues
End Sub

Private Sub Form_Unload(Cancel As Integer)
  SendMail.Shutdown
  Set SendMail = Nothing
End Sub

Private Sub Command1_Click()
  Screen.MousePointer = vbHourglass
  List2.Clear
    
  With SendMail
    .SMTPHostValidation = VALIDATE_HOST_DNS
    .EmailAddressValidation = VALIDATE_SYNTAX
          
    'Adresse des Mailservers, bei der ersten Verwendung der
    'Sendmail.dll ist eine Zuweisung zwingend ansonsten optional
    .SMTPHost = Text1.Text
    
    'E-Mail-Adresse des Absenders, bei der ersten Verwendung der
    'Sendmail.dll ist eine Zuweisung zwingend ansonsten optional
    .From = Text2.Text
    
    'Angezeigter Name des Absenders, die Angabe ist optional und
    'wird falls nicht benannt, nach der ersten Verwendung der
    'Sendmail.dll aus dem Speicher gelesen
    .FromDisplayName = Text3.Text
    
    'E-Mail Adresse des Empfängers, Zuweisung ist zwingend, bei
    'mehreren Empfängern, sind diese durch Kommas oder Semikolons
    'zu trennen
    .Recipient = Text7.Text
    
    'Angezeigte Namen der Empfänger, Angabe ist optional, bei
    'mehreren Empfängern, sind diese durch Kommas oder Semikolons
    'zu trennen
    .RecipientDisplayName = Text6.Text
    
    'E-Mail Adressen der Cc Empfänger, Angabe ist optional, bei
    'mehreren Empfängern, sind diese durch Kommas oder Semikolons
    'zu trennen
    .CcRecipient = Text9.Text
    
    'Angezeigte Namen der Cc Empfänger, Angabe ist optional, bei
    'mehreren Empfängern, sind diese durch Kommas oder Semikolons
    'zu trennen
    .CcDisplayName = Text8.Text
    
    'Die dem Empfänger angezeigte Antwort Adresse, Angabe optional
    .ReplyToAddress = Text2.Text
    
    'Betreff, Subject der E-Mail, Angabe optional
    .Subject = Text10.Text
    
    'Die eigentliche Nachricht, Angabe optional
    .Message = Text11.Text
 
    'String der den absoluten Pfad zu der Datei für den Attachment
    'Anhang) beinhaltet, bei mehreren Dateien, sind diese durch
    'Kommas oder Semikolons zu trennen. Die Verwendung dieses Para-
    'meters ist optional
    .Attachment = Trim(Att)
    
    'True falls der Nachrichten Text HTML enthalten darf, False
    'falls nicht, letzterer ist voreingestellt.
    .AsHTML = HTML
    
    'Basis für eingebettete Links, optional
    .ContentBase = ""
    
    'EncodeType: MIME_ENCODE oder UU_ENCODE,ersterer ist
    'voreingestellt.
    .EncodeType = MyEncodeType
    
    'True falls am Server eine gesonderte Kennwortabfrage erforder-
    'lich ist, False ist voreingestellt.
    .UseAuthentication = AuthLogin
    
    'Übergibt im Zusammenhang mit .UseAuthentication = True die
    'Nutzerkennung, optional
    .Username = Text4.Text
    
    'Übergibt im Zusammenhang mit .UseAuthentication = True das
    'Passwort, optional
    .Password = Text5.Text
    

    'Hier folgen erweiterte Einstellung, nur verwenden falls
    'undedingt erforderlich
    
    'Verbindungs-TimeOut, optional, voreingestellt auf 10s
    '.ConnectTimeout = 10
    
    'Nachrichten-TimeOut, optional, voreingestellt auf 60s
    '.MessageTimeout = 60
    
    'Verbindungs-Wiederholungsversuche, optional, voreingestellt
    'auf 5 mal
    '.ConnectRetry = 5
    
    'Speichern der Kenndaten, optional, voreingestellt auf True
    '.PersistentSettings = True
    
    'Mailsport, optional, voreingestellt auf Port 25
    '.SMTPPort = 25
            
    'Letztendliches Absenden der vorher definierten E-Mail
    .Send
  End With
  Screen.MousePointer = vbDefault
End Sub

Private Sub Command2_Click()
  Dim Ctrl As Control
  
    List1.Clear
    List2.Clear
    Att = ""
    
    For Each Ctrl In Me.Controls
      If TypeOf Ctrl Is TextBox Then Ctrl.Text = ""
    Next Ctrl
    
    Call ProgressBar(0, 0, 100)
    Call RetrieveSavedValues
End Sub

Private Sub Command4_Click()
  If File1.ListIndex <> -1 Then
    List1.AddItem File1.FileName
    If Att = "" Then
      Att = File1.Path & "\" & File1.FileName
    Else
      Att = Att & "," & File1.Path & "\" & File1.FileName
    End If
  End If
End Sub

Private Sub Check1_Click()
  If Check1.Value = vbChecked Then
    AuthLogin = True
    Label1.Visible = True
    Label2.Visible = True
    Text4.Visible = True
    Text5.Visible = True
  Else
    AuthLogin = False
    Label1.Visible = False
    Label2.Visible = False
    Text4.Visible = False
    Text5.Visible = False
  End If
End Sub

Private Sub Check2_Click()
  If Check2.Value = vbChecked Then
    HTML = True
  Else
    HTML = False
  End If
End Sub

Private Sub Option1_Click(Index As Integer)
  If Option1(0).Value = True Then
    MyEncodeType = MIME_ENCODE
  Else
    MyEncodeType = UU_ENCODE
  End If
End Sub

Private Sub Dir1_Change()
  File1.Path = Dir1.Path
End Sub

Private Sub Drive1_Change()
  Dir1.Path = Drive1.Drive
End Sub

Private Sub SendMail_Progress(lPercentCompete As Long)
  Call ProgressBar(lPercentCompete, 0, 100)
End Sub

Private Sub SendMail_SendFailed(Explanation As String)
  MsgBox ("Fehler beim Senden: " & vbCrLf & Explanation)
  Call ProgressBar(0, 0, 100)
End Sub

Private Sub SendMail_SendSuccesful()
  MsgBox "Send Successful!"
  Call ProgressBar(0, 0, 100)
End Sub

Private Sub SendMail_Status(Status As String)
  List2.AddItem Status
  List2.ListIndex = List2.ListCount - 1
End Sub

Private Sub ProgressBar(ByVal Prg%, ByVal Min%, ByVal Max%)
  Dim Fx&
    
    If Prg < Min Or Prg > Max Or Max <= Min Then Exit Sub
    Prg = Int(100 / (Max - Min)) * (Prg - Min)
    
    With Picture1
      Picture1.Cls
      If Prg > 0 Then
        Fx = (Picture1.ScaleWidth - 2) / 100 * Prg
        Picture1.Line (0, 0)-(Fx + 1, Picture1.ScaleHeight - 1), _
                       &H8000000D, BF
        .CurrentX = Fx + 3
        .CurrentY = 0
        Picture1.Print Trim$(CStr(Prg) & " %")
      End If
    End With
End Sub

Private Sub RetrieveSavedValues()
  With SendMail
    Text1.Text = .SMTPHost
    Text2.Text = .From
    Text3.Text = .FromDisplayName
    Text4.Text = .Username
    Option1(.EncodeType).Value = True
  
    If .UseAuthentication Then
      Check1.Value = vbChecked
    Else
      Check1.Value = vbUnchecked
    End If
  End With
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Kommentar von Lothar Kriegerow am 20.09.2010 um 13:17

Hallo,
dieser Code funktioniert teilweise super. Soll aber einen Email an eine neuen EMAIL-Account mit der Extension .eu oder .info, so wird diese Email als Fehler erkannt. Gibt es irgendwo ein Update der SendMail?

Danke schon jetzt - Lothar

Kommentar von Michael L am 06.05.2010 um 15:20

Hallo,
ich habe von dem eine EXE-Datei erzeugt und auf einem anderen PC installiert. Die vbsendmail.dll habe ich nach C:\WINDOWS\system32 kopiert. Beim Starten des Programms bekomme ich die Fehlermeldung: "Run-time error '429': ActiveX component can't create object".
Woran liegt das?

Kommentar von Carlo Heller am 02.07.2008 um 09:43

Hallo,
danke für das Programm, das ist genau das, was ich brauche.
Nur leider bekomme ich es nicht zum laufen.
Die DLL "vbSendMail.dll" habe ich heruntergeladen und in das Windowsverzeichnis kopiert.
Jetzt kommt die Meldung "Objekterstellung durch AktiveX-Komponente nicht möglich" in der Zeile "Set SendMail = New clsSendMail".
Woran liegt das?
Danke für die Antwort im voraus.
Carlo

Kommentar von Franzi am 11.02.2008 um 11:33

Hallo! Das funkt alles wunderbar, solange ich Mails an mich selber sende. Wenn ich aber mehrere Mails an verschiedene Empfänger sende, erhalte ich die verschiedensten "Mail delivery failed"-Meldungen zurück. Der Hintergrund: ich erstelle die Mails und speichere sie in einer Db, wenn alle Mails fertig sind versuche ich sie in einem Schwung zu senden, per Loop. Die Mails gehen an einen oder mehrere Empfänger und haben ein oder mehrere Attachments und der Messagetext liegt als Html-Datei vor. Den Message-Text binde ich wie im Tip angegeben ein. Der Tenor der Meldungen besagt

LMTP Error after DATA: 554 5.6.0 Message contains NUL characters

und ähnliche Meldungen, je nach Provider etwas unterschiedlich dargestellt. Die Html-Dateien erstelle ich mit Word 2002. Wie bekomme ich die NUL-Characters weg? Gruß Franz

Kommentar von rj am 06.12.2007 um 22:26

den Code gibt es hier: code/vbSendMail.zip
die SendMail.cls ist der eigentliche Code...

Kommentar von wasi1 am 18.04.2006 um 17:09

Hat jemand schon den Code von der vbSendMail.dll bekommen?

Dann schickt sie mir doch bitte zu.
An: wasi@cool-brother.de

Gruß Wasi...

Kommentar von Erwin am 02.02.2006 um 21:11

ich verwende Aol für den email versand.
nach unzähligen Versuchen wird nun die Verbindung aufgebaut, aber es erscheint dann folgende Meldung:

Syntax Error in Parameters or Arguments

Verändert habe ich den Port auf 587

Viele Grüße
Erwin

Kommentar von Hubert Holler am 07.11.2005 um 23:14

Wie kann man einen Formatierten Text schicken. D.h. ich habe versucht eine RichTextbox in VB zu verwenden und habe dort auf Arial und eine den Text eingefärbt. Nur wenn ich das e-mail als html versende wird dieses Format nicht mitgeschickt.

Hoffe da kann mir jemand weiterhelfen.

Vielen Dank

Kommentar von duygu am 25.10.2005 um 15:15

Hallo liebe Helfer und Helferinnen
ich habe das Problem, dass jedesmal, wenn ich den Computer einschalte,die Warning bekomme,dass " Die Komponente 'MSWINSCK.OCX' fehlt oder eine meiner Abhängigkeiten nicht registriert ist.ich habe schon mal probiert bei der KOMPONENETENDIENSTE was zu machen,es hat aber leider nicht geklappt.Kann mir jemand weiter helfen oder eine Alternative nennen?
Ich bedanke mich im Voraus bei denen, die mir hilfreich sein können...

Kommentar von Walter am 18.08.2005 um 21:30

Hallo,
gibt es bereits eine Lösung für die SMTP-Authentifikation Problem bei "1und1(Puretec)".

Kommentar von Bedran am 26.05.2005 um 12:12

ich habe das Problem, das beim Compilieren die VBSENDMAIL.DLL nicht gefunden wird weil der Verweis der entsprechenden Bibliothek nicht vorhanden ist! Können sie mir bitte eine Lösung schicken. mir gehts nur darum eine Datei per E-Mailanhang zu schicken. ich wollte das ganze mit der ShellExecute realisieren aber die Datei erscheint nicht im anhang:


beispiel:

...
lFileName = "D:\test.txt"

ls = "mailto:mustermann@web.de"
ls = ls & "?subject=Hilfe"
ls = ls & "&body=Mehr Hilfe ölsdfölskflösdf sdfksölfkslödfks"
ls = ls & "&Attach=" & lFileName

Kommentar von Romik am 23.05.2005 um 09:08

Hallo Volker,

z.B. bei FreeVBCode:
http://www.freevbcode.com/ShowCode.Asp?ID=109

Kommentar von Volker Sittler am 20.05.2005 um 16:53

Hallo,
ich Suche die Datei vbSendMail.dll und kann Se beim besten willen nicht finden

Kommentar von ein Interessent am 20.01.2005 um 21:37

Kann man auch irgendwie den Code von der dll vbSendMail.dll bekommen? weil ich persönlich nutze nicht gerne "fremde" DLL's

Kommentar von assel am 15.01.2005 um 00:33

Bei Tipp 260, ist bei mir bei "Attribute SendMail.VB_VarHelpID = -1" ein Syntaxfehler, was kann ich da machen?

Kommentar von Romik am 08.10.2004 um 09:26

Hallo Tino!

Registrieren Sie die vbSendmail.dll neue - dann muss das Problem weg sein.

regsvr32 -u %windir%\system32\vbSendmail.dll
regsvr32 %windir%\system32\vbSendmail.dll

Kommentar von Tino am 08.10.2004 um 09:13

Das Beispiel hat super funktioniert, allerdings ist das Datum der Mail die man versendet immer 01.01.1970. Kann man dies beeinflussen?

Kommentar von byte2702 am 02.10.2004 um 11:33

OK Leute, Ihr habt Recht: Laut http://support.microsoft.com/default.aspx?scid=kb;EN-US;194751 sind die MAPI-Controls und Winsock Controls nicht in der VB6 Einsteiger Edt. enthalten. Damit wird deren Lizensierung nicht supported. Wahrscheinlich steht im Header der OCX-Datei: if (Installed == 'VB6-E') { goto FastExit; }. Entweder ersteigert man die Enterprise- oder Professional-Edition bei eBay oder man baut die SMTP-Engine unter C/C++ oder Delphi oder PHP/CGI (über WWW), und kompliliert diese dann getrennt. Und übergibt dann die Befehle über Parameter über Shell. C/C++ gibt es kostenlos im Internet (Borland oder openwatcom.org), Borland Delphi gibt es manchmal kostenlos in PC-Magazinen auf CD und PHP (über WWW) erfordert nur einen Provider, dessen Webserver PHP unterstützt (so wie CGI). Wer sich mit OCX-Files auskennt, kann natürlich versuchen, in diese mal reinzugucken. :-)

Kommentar von byte2702 am 01.10.2004 um 21:06

Bzw. Zwecks der Fehlermeldung, dass z.B. das MAPI-Control nicht registriert werden konnte: http://support.microsoft.com/default.aspx?scid=kb;en-us;177799 (mittlerer Teil).

Kommentar von byte2702 am 01.10.2004 um 19:37

Zwecks der Fehlermeldung, dass z.B. das MAPI-Control nicht registriert werden konnte (VB6 Einsteiger Edt.): Der Link http://support.microsoft.com/default.aspx?scid=kb;en-us;193366 bringt u.U. Abhilfe. Dort das entspr. Control als CAB-Datei herunterladen und in einen Ordner entpacken. Es wird dann in der Regel eine OCX-Datei (ActiveX-Control) und eine INF-Datei (Setup-Information) entpackt. Die dazugehörige INF-Datei einfach mit der rechten Maustaste anklicken und Installieren auswählen. Damit wird dann die OCX-Datei in den richtigen Ordner gepackt und auch korrekt registriert.

Kommentar von Romik am 30.09.2004 um 13:52

Hallo dAu1!

Sie brauchen MSWINSCK.OCX in %SYSTEM32%-Verzeichnis. Sie ist bestimmt nicht da.(Ist, z.B., unter Win2000-Server/WinNT4.0-Server der Fall). Man kann aber diese Datei einfach von jedem laufenden System (z.B. Win2000-Prof) umkopieren.

Kommentar von dAu1 am 15.09.2004 um 13:25

Unter VB5 funktioniert es bei mir leider nicht:
Fehler: Das Steuerelement 'Winsock' konnte nicht aus 'MSWINSCK.OCX' geladen werden.

Hat jemand eine Idee?
Danke

Kommentar von Bruno Anzt am 17.08.2004 um 14:47

Habe Tipp 0260 unter VB5 ausprobiert funktioniert super.
Wie kann man das Info-Fenster nach erfolgreichem Versenden einer E-Mail unterdrücken? Könnte jemand die DLL VBSENDMAIL hierzu anpassen - mir fehlen dazu leider die Kenntnisse.

Danke

Kommentar von Pat am 21.07.2004 um 10:37

Zum Beispiel hier:
http://www.freevbcode.com/ShowCode.Asp?ID=109

Kommentar von Michael am 24.06.2004 um 14:55

wo finde ich den die vbsenmail.dll - jede suche war erfolglos

Kommentar von Axel F. am 25.05.2004 um 21:25

Bei mir funktioniert es unter Windows 2000, XP und XP Prof. einwandfrei. Nur auf 2003 Server wird das Programm abgebrochen und ich finde im Windows-Ereignisprotokoll folgenden Eintrag:

Fehler in Warteschlange: Fehlgeschlagene Anwendung mail.exe, Version 1.2.0.0, fehlgeschlagenes Modul ntdll.dll, Version 5.2.3790.0, Fehleradresse 0x00004f60.

Das Programm selbst liefert keine Fehlermeldungen und wird während des Sendevorgangs durch die DLL abgebrochen.

Kommentar von Michael Zapf am 15.05.2004 um 13:13

Hallo Winterholler!

Bei Anbietern wie GMX, WEB.DE,... muss, bevor eine Mail verschickt werden kann, der POP3-Server benutzt werden.

Versuche, dich vorher irgendwie am POP3-Server anzumelden.
Wie das geht, fragst du am besten im Forum.

Kommentar von Winterholler am 11.05.2004 um 22:26

Ich bekomme immer die Fehlermeldung "5.0.7" zuerst am Pop3-Server anmelden.

Wie kann ich diesen Fehler umgehen. Ich habe im Moment einen GMX-Account.

Kommentar von AQ200 am 08.02.2004 um 18:14

Hallo,
bin Programmieranfänger und benötige eigentlich nur eine kleine email-Funktion: ich möchte über die .dll lediglich eine email versenden, ohne das das Programm gestartet werden soll und über Tastatur oder Maus Eingaben gemacht werden sollen - der Nachrichtentext wird über Script eingefügt (hab ich auch im auch schon im Griff). Alle anderen Parameter, wie Empfänger etc. sind immer gleich.
Was muß ich tun, um die notwendigen Befehle über die .dll ausführen zu können?

Kommentar von Helge Rex am 07.01.2004 um 15:33

Das hier ist nicht unser Forum, sondern ein Tipp.
Die Bemerkungen der User unter dem Tipp sind reine Notizen.

Wenn ihr Fragen zum Tipp habt, dann stellt diese bitte in unserem Forum:
http://foren.activevb.de/cgi-bin/foren/list.pl?forum=4
Ihr braucht Euch dafür nicht registrieren.

@Zoltan Feteke:
"Rücksprache erwünscht" ist ein Feature Deines MailClients.
Was Du wo eintragen mußt, um dieses Feature nutzen zu können, mußt Du Dir im Quelltext einer Deiner Emails anschauen.

Kommentar von EddSo am 23.12.2003 um 15:57

Das stimmt hier antwortet wirklich keiner aber des proggi FUNZT. Danke dafür, ist ein guter rohstoff

Kommentar von Z.Fekete am 05.09.2003 um 13:55

Das ist das beste Forum
Da kann man beliebig Fragen stellen, ein Antwort komm so wie so nicht
MfG: Zoltán

Kommentar von Uwe am 05.09.2003 um 13:50

Auch ich suche eine Lösung für die SMTP-Authentifikation bei "1und1(Puretec)".

Kommentar von Dhissi am 01.09.2003 um 10:25

Hallo Leute,
wie kann man die Format der Email im Outlook herausbekommen, ob es Text, Html oder Rich-Text
mfg Dhissi

Kommentar von Lowrey am 20.08.2003 um 17:14

Hi,
ich hab mit SendMail ein Prog erstellt, welches auch prima läuft. Wenn ich das Prog auf einem anderen Rechner install. funktioniert SendMail nicht mehr. Keine Fehlermeldung, einfach nur kein Connect möglich. Wenn ich jetzt meine VB-Umgebung auf dem Rechner install. läuft es. Wenn ich VB deinstall. nicht mehr.
Woran kann das liegen?
Fehlt noch eine andere dll?

Dank

Lowrey

Kommentar von Matthias am 06.07.2003 um 14:39

Hat jemand eine Idee für eine funktionierende SMTP-Authentifizierung?

Kommentar von Puri am 14.06.2003 um 15:32

Gibts noch ne Alternative, die die SMTP-Authentifizierung unterstützt?

Kommentar von Zoltan Fekete am 12.06.2003 um 17:52

Noch etwas:
Ich habe die Fragen durchgelesen. Wo sind die Antworten ? :)
Zoltán

Kommentar von Z. Fekete am 12.06.2003 um 17:48

Eine der besten VB Tools, was ich bisher gesehen habe.
3 Fragen:
- wo kann ich beeinflussen die Sendedatum. Bei mir erscheint 2003.01.12.
- wie kann ich HTML senden-nicht als Anhang
- wo kann ich einschalten, das ich Rückmeldung bitte
MfG: Zoltán Fekete - Ungarn

Kommentar von Fritz Raab am 28.05.2003 um 00:42

beim versenden einer mail mit dem programm wird mir die fehlermeldung "version von winsock.ocx = outdatet" angezeigt, dann hängt sich vb auf. Ich habe vb5 und win2000. könnt ihr mir da weiterhelfen?

Kommentar von Uwe Reich am 28.03.2003 um 14:40

Hallo Leute,

das Teil funktioniert super!!!

Frage: Wie läßt sich verhindern, das der Aufruf Set SendMail = New clsSendMail' beim Laden des Formulars eine Internet-Verbindung aufgebaut.
Gibt es ein versteckten Schalter?

Kommentar von Zoltan Fekete am 01.12.2002 um 14:13

Die "Tipp 0260: Mails versenden mit Attachments" ist sehr nützlich, 1A. Eine einzige Frage bleibt für mich offen: wie kann ich die Option "Rücksprache gewünscht" einstellen?

Kommentar von Bob am 22.10.2002 um 11:23

Die SMTP-Authentifikation tut definitiv net. was soll ich tun?

Kommentar von Matthias Emmel am 16.10.2002 um 11:50

Nachtrag.
Ich möchte HTML Seiten ohne Anhang senden. Auf den Seiten sind Bilder die ich aber !!!nicht!!! mit Pfad aus dem Internet laden will sondern direkt im mail mitschicken möchte.
Wer kann mir helfen ?

Kommentar von Matthias Emmel am 16.10.2002 um 11:25

Super Teil!!
Ich möchte HTML Seiten versende ohne Anhang. Wie binde ich die Bilder dazu ??
Vielen Danl

Kommentar von Jürgen am 15.10.2002 um 21:09

Auch ich suche eine Lösung für die SMTP-Authentifikation bei "1und1(Puretec)". Ich weiß nur, dass deren Methode nicht die in VBSENDMAIL.DLL enthaltenen Methoden PLAIN und NONE sondern LOGIN ist.
Wer kann helfen?

Kommentar von Gerhard am 15.08.2002 um 09:29

Die SMTP-Authentifikation funktioniert zumindest bei "1und1(Puretec)" nicht. Für einen Tipp wäre ich sehr dankbar!

Kommentar von Arci am 27.05.2002 um 18:16

Ihr müsst die entsprechenden Berechtigungen einstellen. Dem Verzeichnis wo die DLL liegt den IUSR hinzufügen.

Kommentar von Andy am 08.05.2002 um 07:54

Bei mir ist die dll aber registriert und eingebunden! Es tritt aber das Problem von 28 und 29 auf! Was kann ich machen?

Kommentar von Philipp Weber am 10.04.2002 um 20:21

ZU 28
Ich schätze mal das die dll nicht registriert ist.
Der Fehler kommt
a) Wenn sie nich da is
b) wenn sie nich registriert ist
vielleicht auch noch bei ein ein paar anderen fällen die kenn ich aber (noch nicht)
Philipp

Kommentar von Art am 28.03.2002 um 01:56

Zu 28 + 29
Ihr müsst zuerst die DLL erstellen und dann unter Referenzen in Euer Programm einbinden.
Dann sollte es klappen.
Art

Kommentar von Florian Stieger am 10.03.2002 um 16:09

Ich habe genau das selbe Problem wie Nr. 28! Kann mir jemand helfen! Danke

Kommentar von Gerald am 10.03.2002 um 13:17

Leider habe ich ein Problem in der Form Load()
Set SendMail = New clsSendMail
'Objekterstellung durch ActiveX-Komponente nicht möglich
ich hab mir die vbSendMail.dll Version 3.52 heruntergeladen!!
was ist da los?
mfg Gerald

Kommentar von Art am 07.03.2002 um 03:03

Hi Guys,
You can download the newest Version of the required Dll with full Source Code at
http://www.freevbcode.com/ShowCode.Asp?ID=109
Have Fun
Art

Kommentar von Hamir am 19.01.2002 um 15:41

Das klappt ja ganz gut aber wie geht das mit empfangen von E-Mails mit Attachments

Kommentar von dddd am 10.01.2002 um 12:32

ddd

Kommentar von jonas am 13.12.2001 um 14:39

Coole Sache,
Auf windows 2000 werde ich jedoch vermehrt von "Runtime 40006 Wrong Protocol or connectionstate for the requested transaction or request" Hat da jemand ein Idee?
Passiert meist dann, wenn sehr viele Mails hintereinander geschickt werden

Kommentar von Niklas am 26.10.2001 um 16:54

Habe Probleme eine EMail mit NT4 zu versenden!! Ht jemand einen Tip.

Kommentar von Ralf am 19.10.2001 um 16:06

Beim Versenden von Mails mit Anhang bricht SendMail die übertragung nach 10 min. ab! Das hat nichts mit den Timeout-Parametern zu tun. Gibts noch einen Parameter um das Problem zu umgehen?

Kommentar von rolX am 22.08.2001 um 07:18

Habe gleiches problem wioe Frage 14: Kann man vbSendMail auch ohne Winsock verwenden? Benutze VB6 Einsteiger Edition, die hat kein MAPI und kein WINSOCK. Ich erhalte beim Mailsenden mit diesem Beispielprogramm die Fehlermeldung:
Fehler beim Senden:
Die Komponente 'MSWINSCK.OCX' oder eine ihrer Abhängigkeiten ist nicht registriert. Eine Datei fehlt oder ist ungültig
Kann mir jemand weiter helfen oder eine Alternative nennen?

Kommentar von Kai am 08.08.2001 um 15:11

Hi!
Warum wird bei uns eine Internet-Verbindung aufgebaut, wenn 'Set SendMail = New clsSendMail' ausgeführt wird? Im Form.Load ausgeführt wartet das Formular so lange, bis die Verbindung steht...
Ciao, Kai

Kommentar von Michael Lorenz am 27.05.2001 um 11:04

Ist es möglich die, mit diesem Prog. verschickten E-mails (mit Anhang!!!), auch wieder mit einem VB Programm zu empfangen und dann das Atatchment auf der FP abzuspeichern?
Danke für Antworten :-)

Kommentar von Roger Strebel am 14.05.2001 um 16:08

Grossartig!
Funktioniert alles bestens! Als einziges SendMail sogar als Geplanter Task, wenn man nicht eingeloggt ist.

Kommentar von Roger Strebel am 14.05.2001 um 13:21

Grossartig!
Funktioniert auch unter NT4, wenn man die VB-Applikation als geplanten Task aufruft.
Frage: Kann man die Headers ausschalten (Content-Type,...). Sie stören, wenn die Mail als SMS versandt wird
Rog

Kommentar von Christian Arens am 04.05.2001 um 20:36

SendMail funktioniert eigentlich ganz prima und problemlos, 2 (kleine) Bugs sind mir trotzdem aufgefallen:
1.) Attachments mit Umlaut im Dateinamen (ich weiß - sowas macht man nicht - gibt aber trotzdem genug Leute, die's versuchen):
Die Umlaute werden nicht übertragen, auch nicht im ausschließlich deutschen Sprachraum. Ist aber weniger tragisch.
2.) Der in der verschickten Mail enthaltene Zeitstempel ist im Format der lokalen Datumseinstellungen, also bei mir deutsche Monatsnamen. Im April hat alles gut geklappt - kein Wunder! Die erste Mail im Mai kam dann aber scheinbar nicht an, aber auch nur scheinbar, da Outlook "May" erwartet hätte und mit dem Datum nichts anfangen konnte. Die Mail wurde dann zwischen den alten Mails im Januar einsortiert und war erst mal nicht auffindbar. Ich konnte den Fehler mit meinem lokalen Mailserver (Jana) nachvollziehen, nach manueller Änderung in der Mail vor Abholung durch den Client von "Mai" nach "May" klappte dann alles.
Kennt jemand einen Workaround (bitte nicht "Datumsformat englisch" einstellen) oder gibt eine neuere Version der DLL?

Kommentar von Sascha Kraus am 03.05.2001 um 19:01

Wenn ich auf senden klicke, kommt: Command unrecognized
Wieso??? Danke

Kommentar von FLORIAN am 18.04.2001 um 10:58

Hi!
Wi kann man denn eMails empfangen, OHNE winsock?

Kommentar von Pascal am 27.03.2001 um 09:15

Auch ich kann die vbsendmail.dll patu nicht finden?!?!? Hilfe!!

Kommentar von Jens Brusnen am 23.02.2001 um 15:44

Ich kann das Projekt gar nicht erst starten. Fehlermeldung "Kann Objekt nicht durch ActiveX-Komponente erzeugen" (so in etwa).
Brauche dringend Hilfe!

Kommentar von Matthias Ahrens am 06.02.2001 um 21:50

Hallo!
Eure Sendmail funzt echt super unter W2000, leider schaffe ich es nicht sie unter NT4.0 zum laufen zu bringen. Hat jemand ein Tipp wie sich dieses bewerkstelligen läßt??
Vielen Dank schon im voraus.

Kommentar von emi am 01.02.2001 um 20:21

wieso finde ich die dll nicht ??
kann mich mal bitte einer aufklären !
es kann doch nicht wahr sein, daß ich der einzige bin der sie nicht findet !

Kommentar von Sigi am 10.01.2001 um 10:19

Sorry,
die Meldung betrifft die mswinsck.ocx (Fehlermeldung: outdated)
Mein Ziel ist es automatisierte Mails im HTML-Format zu versenden. Über einen Tipp würde ich mich sehr freuen!

Kommentar von Sigi am 10.01.2001 um 10:13

Hallo,
ich habe da ein kleines Problem! Beim PRG-Start bekomme ich die Meldung vbmail outdatet!

Kommentar von Hannes am 28.11.2000 um 23:28

Damit ist auch diese Frage beantwortet. Ich war zu blöd!

Kommentar von Hannes am 28.11.2000 um 23:20

Hallo Leute, ich frage nur ungerne, aber ich finde die vbSendMail.dll nicht. Bin ich zu blöde, oder ist das gute Teil wirklich nicht mehr da?

Kommentar von Stephan Schröder am 14.11.2000 um 00:22

Kennt auch jemnand eine Möglichkeit das gleich in Access zu tun ? Aber nicht mit dem docmd. Befehl, mit ihm kann man nur Berichte als Attachments schicken ! Danke

Kommentar von Jürgen am 11.11.2000 um 20:21

Bin am verzweifeln, nachdem ich die Dll gefunden, ins system32 verzeichnis bei Win 2k kopiert und registriert habe geht das programm einfach nicht.
nach ausfüllen der form und senden bekomme ich folgende meldung:
Your attempt to send mail failed for the following reason: syntax error (#5.5.4)
Ich weiss nun nicht mehr weiter, habe das Orginal Beispiel ohne Veränderung unter VB6 und Win2k genommen.
Wer kann helfen ?

Kommentar von Götz Reinecke am 02.11.2000 um 00:03

Mhm, ich verstehe das ehrlich gesagt nicht, wir arbeiten jetzt schon seit Monaten mit dieser DLL (Win95/Win98) ohne daß es irgendwelche Probleme damit gab.
Ihr habt die DLL schon ins Systemverzeichnis kopiert und danach ohne Fehlermeldung zur Registratur gebracht? Und auch die Einbindung unter Projekte/Verweise gemacht?
Ist dies der Fall sollte eigentlich alles einwandfrei funktionieren.

Kommentar von Bufo am 01.11.2000 um 09:22

Hallo,
wenn ich versuche, die Sendmail.dll meinem Projekt hizuzu-
fügen, bekommen ich jedesmal éine Fehlermeldung.
Habe es auf verschiedenen Systemen ausprobiert,ist überall gleich :"Fehler beim Öffnen einer DLL."Auch Versuche,die DLL mit Regsvr32 zu registrieren,haben das Problem nicht gelöst.Wie kann ich die Sache ans Laufen bekommen??

Kommentar von Hakan Genc am 29.10.2000 um 15:19

Hallo!
Ihr habt das zwar schon sehr gut hin bekommen aber email senden funktioniert immer noch nicht...warum? also ich habe das immer noch nicht geschaft.
Falls ihr das schaft, könntet ihr mir einen fertig beispiel geben mit resourcen...?