Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0138: Option-Buttons im Menü

VB 5/6-Tipp 0138: Option-Buttons im Menü

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: AppendMenuA (AppendMenu), CallWindowProcA (CallWindowProc), CheckMenuRadioItem, GetMenu, GetSubMenu, GetSystemMenu, SetWindowLongA (SetWindowLong)

Download: Download des Beispielprojektes [2,86 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit
       
Private Declare Function GetSystemMenu Lib "user32" (ByVal _
        hwnd As Long, ByVal bRevert As Long) As Long
        
Private Declare Function AppendMenu Lib "user32" Alias _
        "AppendMenuA" (ByVal hMenu As Long, ByVal wFlags As _
        Long, ByVal wIDNewItem As Long, ByVal lpNewItem As _
        String) As Long
               
Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hwnd As Long, ByVal MSG As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
        
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Private Declare Function GetMenu Lib "user32" (ByVal _
        hwnd As Long) As Long
        
Private Declare Function GetSubMenu Lib "user32" (ByVal _
        hMenu As Long, ByVal nPos As Long) As Long
        
Private Declare Function CheckMenuRadioItem Lib "user32" _
        (ByVal hMenu As Long, ByVal un1 As Long, ByVal _
        un2 As Long, ByVal un3 As Long, ByVal un4 As Long) _
        As Long

Const MF_STRING = &H0&
Const MF_SEPARATOR = &H800&
Const MF_BYCOMMAND = &H0&

Const GWL_WNDPROC = (-4&)
Const WM_SYSCOMMAND = &H112
Const WM_COMMAND = &H111

Dim PrevWndProc&

Private Function WndProc(ByVal hwnd As Long, ByVal MSG As Long, _
                         ByVal wParam As Long, ByVal lParam As _
                         Long) As Long
  
  Dim mnuHandle&
  
    If MSG = WM_SYSCOMMAND Then
      If wParam >= &H200 And wParam <= &H203 Then
        mnuHandle = GetSystemMenu(Form1.hwnd, False)
        Call CheckMenuRadioItem(mnuHandle, &H200, &H203, wParam, _
                                MF_BYCOMMAND)
      End If
    ElseIf MSG = WM_COMMAND Then
      mnuHandle = GetMenu(Form1.hwnd)
      If wParam >= &H2 And wParam <= &H5 Then
        mnuHandle = GetSubMenu(mnuHandle, 0)
        Call CheckMenuRadioItem(mnuHandle, &H2, &H5, wParam, _
                                MF_BYCOMMAND)
      ElseIf wParam >= &H7 And wParam <= &HA Then
        mnuHandle = GetSubMenu(mnuHandle, 1)
        Call CheckMenuRadioItem(mnuHandle, &H7, &HA, wParam, _
                                MF_BYCOMMAND)
      End If
    End If
  
    WndProc = CallWindowProc(PrevWndProc, hwnd, MSG, wParam, lParam)
End Function

Public Sub Init(hwnd&)
  Dim mnuHandle&, mnuSubHandle&
  mnuHandle = GetSystemMenu(hwnd, False)
  
  Call AppendMenu(mnuHandle, MF_SEPARATOR, 0, "")
  Call AppendMenu(mnuHandle, MF_STRING, &H200, "B&efehl 1")
  Call AppendMenu(mnuHandle, MF_STRING, &H201, "Be&fehl 2")
  Call AppendMenu(mnuHandle, MF_STRING, &H202, "B&efehl 3")
  Call AppendMenu(mnuHandle, MF_STRING, &H203, "Be&fehl 4")
  
  Call CheckMenuRadioItem(mnuHandle, &H200, &H203, &H200, _
                          MF_BYCOMMAND)
  
  mnuHandle = GetMenu(Form1.hwnd)
  mnuSubHandle = GetSubMenu(mnuHandle, 0)
  Call CheckMenuRadioItem(mnuSubHandle, &H2, &H5, &H2, MF_BYCOMMAND)
  
  mnuSubHandle = GetSubMenu(mnuHandle, 1)
  Call CheckMenuRadioItem(mnuSubHandle, &H7, &HA, &H7, MF_BYCOMMAND)
  
  PrevWndProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WndProc)
End Sub

Public Sub Terminate(hwnd&)
  Call SetWindowLong(hwnd, GWL_WNDPROC, PrevWndProc)
End Sub
'---------- Ende Modul "Module1" alias Module1.bas ----------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Beschriftungsfeld "Label1"
' Steuerelement: Menü "mnuMenü"
' Steuerelement: Menü "a" auf mnuMenü
' Steuerelement: Menü "b" auf mnuMenü
' Steuerelement: Menü "c" auf mnuMenü
' Steuerelement: Menü "d" auf mnuMenü
' Steuerelement: Menü "mnuExtras"
' Steuerelement: Menü "e" auf mnuExtras
' Steuerelement: Menü "f" auf mnuExtras
' Steuerelement: Menü "g" auf mnuExtras
' Steuerelement: Menü "h" auf mnuExtras
Option Explicit

Private Sub Form_Load()
  Call Init(Me.hwnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate(Me.hwnd)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.