Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0134: CheckButtons im Systemmenü

VB 5/6-Tipp 0134: CheckButtons im Systemmenü

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: AppendMenuA (AppendMenu), CallWindowProcA (CallWindowProc), CheckMenuItem, GetMenuState, GetSystemMenu, SetWindowLongA (SetWindowLong)

Download: Download des Beispielprojektes [2,67 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Beschriftungsfeld "Label1"
Option Explicit

Private Sub Form_Load()
  Call Init(Me.hwnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate(Me.hwnd)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit
       
Private Declare Function GetSystemMenu Lib "user32" (ByVal _
        hwnd As Long, ByVal bRevert As Long) As Long
        
Private Declare Function AppendMenu Lib "user32" Alias _
        "AppendMenuA" (ByVal hMenu As Long, ByVal wFlags As _
        Long, ByVal wIDNewItem As Long, ByVal lpNewItem As _
        String) As Long
        
Private Declare Function GetMenuState Lib "user32" (ByVal _
        hMenu As Long, ByVal wID As Long, ByVal wFlags As _
        Long) As Long
        
Private Declare Function CheckMenuItem Lib "user32" (ByVal _
        hMenu As Long, ByVal wIDCheckItem As Long, ByVal _
        wCheck As Long) As Long
        
Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hwnd As Long, ByVal MSG As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
               
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Const MF_STRING = &H0&
Const MF_SEPARATOR = &H800&
Const MF_UNCHECKED = &H0&
Const MF_CHECKED = &H8&
Const MF_BYCOMMAND = &H0&

Const GWL_WNDPROC = (-4&)
Const WM_SYSCOMMAND = &H112
Const WM_COMMAND = &H111

Dim PrevWndProc&, mnuHandle&

Private Function WndProc(ByVal hwnd As Long, ByVal MSG _
                         As Long, ByVal wParam As Long, _
                         ByVal lParam As Long) As Long
  Dim Result&
  
    If MSG = WM_SYSCOMMAND Then
      Select Case wParam
        Case &H200:
          Result = GetMenuState(mnuHandle, &H200, MF_BYCOMMAND)
          If Result And MF_CHECKED Then
            Call CheckMenuItem(mnuHandle, &H200, MF_BYCOMMAND _
                               Or MF_UNCHECKED)
            Form1.Caption = "Befehl 1 UnChecked"
          Else
            Call CheckMenuItem(mnuHandle, &H200, MF_BYCOMMAND _
                               Or MF_CHECKED)
            Form1.Caption = "Befehl 1 Checked"
          End If
                  
        Case &H201:
          Result = GetMenuState(mnuHandle, &H201, MF_BYCOMMAND)
          If Result And MF_CHECKED Then
            Call CheckMenuItem(mnuHandle, &H201, MF_BYCOMMAND _
                               Or MF_UNCHECKED)
            Form1.Caption = "Befehl 2 UnChecked"
          Else
            Call CheckMenuItem(mnuHandle, &H201, MF_BYCOMMAND _
                               Or MF_CHECKED)
            Form1.Caption = "Befehl 2 Checked"
          End If
      
         '... etc
      End Select
    End If
  
    WndProc = CallWindowProc(PrevWndProc, hwnd, MSG, wParam, lParam)
End Function

Public Sub Init(hwnd&)
  mnuHandle = GetSystemMenu(hwnd, False)
  
  Call AppendMenu(mnuHandle, MF_SEPARATOR, 0, "")
  Call AppendMenu(mnuHandle, MF_STRING, &H200, "B&efehl 1")
  Call AppendMenu(mnuHandle, MF_STRING, &H201, "Be&fehl 2")
  
  PrevWndProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WndProc)
End Sub

Public Sub Terminate(hwnd&)
  Call SetWindowLong(hwnd, GWL_WNDPROC, PrevWndProc)
End Sub
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 2 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.