Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0095: Eigenes Programmsymbol in der Systemtray anzeigen

 von 

Beschreibung 

Jeder kennt sie, die futzeligen Bildchen, meist unten rechts in der Ecke gelegen. Das geht auch mit VB. Neben dem Darstellen eines beliebigen Symbols und dem einschlägigem Starten des zugehörigen Progamms nach einem Doppelklick auf dieses, kann hiermit auch ein PopUp-Menü eingespielt werden. Weiterhin kann zwischen Klick & Doppelklick mit der rechten bzw. linken Maustaste reagiert werden. Auch ein MouseMove-Ereignis und die Möglichkeit des ToolTipTextes gibt es.

Aktualsierung durch Frank Schüler (12. Januar 2008):
In der Vorversion gab es immer das Problem, das das Kontextmenü nicht verschwand, wenn man nicht einen Menüpunkt im Kontextmenü auswählte. Durch den Aufruf von SetForegroundWindow vor dem Anzeigen des Kontextmenüs wird dieses Problem behoben. Im Prinzip wurde nur der KB Artikel Q135788 in den Tipp aufgenommen.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

SetForegroundWindow, Shell_NotifyIconA (Shell_NotifyIcon)

Download:

Download des Beispielprojektes [3,43 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Bildfeld-Steuerelement "Picture1"
' Steuerelement: Menü "mnBar"
' Steuerelement: Menü "mnNix" auf mnBar
' Steuerelement: Menü "mnBeep" auf mnBar
' Steuerelement: Menü "mnuChange" auf mnBar
' Steuerelement: Menü "mnExit" auf mnBar
' Steuerelement: Menü "mnMsgShow" auf mnBar
Option Explicit

Private Declare Function Shell_NotifyIcon Lib "shell32" _
                         Alias "Shell_NotifyIconA" ( _
                         ByVal dwMessage As Long, _
                         ByRef pnid As NOTIFYICONDATA) As Boolean
                         
Private Declare Function SetForegroundWindow Lib "user32" ( _
                         ByVal hwnd As Long) As Long
                         
Private Const NIM_ADD As Long = &H0&
Private Const NIM_MODIFY As Long = &H1&
Private Const NIM_DELETE As Long = &H2&

Private Const NIF_MESSAGE As Long = &H1&
Private Const NIF_ICON As Long = &H2&
Private Const NIF_TIP As Long = &H4&

Private Const WM_MOUSEMOVE As Long = &H200&
Private Const WM_LBUTTONDOWN As Long = &H201&
Private Const WM_LBUTTONUP As Long = &H202&
Private Const WM_LBUTTONDBLCLK As Long = &H203&
Private Const WM_RBUTTONDOWN As Long = &H204&
Private Const WM_RBUTTONUP As Long = &H205&
Private Const WM_RBUTTONDBLCLK As Long = &H206&

Private Type NOTIFYICONDATA
    cbSize As Long
    hwnd As Long
    uId As Long
    uFlags As Long
    ucallbackMessage As Long
    hIcon As Long
    szTip As String * 64
End Type

Private TIcon As NOTIFYICONDATA

Private Sub Form_Load()

    Me.Hide
    App.TaskVisible = False
    mnBar.Visible = False
    
    TIcon.cbSize = Len(TIcon)
    TIcon.hwnd = Picture1.hwnd
    TIcon.uId = 1&
    TIcon.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    TIcon.ucallbackMessage = WM_MOUSEMOVE
    TIcon.hIcon = Me.Icon
    TIcon.szTip = "Was soll ich dazu sagen" & Chr$(0)
    
    ' Hinzufügen des Icons in den Systemtray
    Call Shell_NotifyIcon(NIM_ADD, TIcon)
    
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)

    Form1.Hide
    
    If UnloadMode = vbAppWindows Or UnloadMode = vbFormCode Then
    
        ' Icon aus dem Systemtray entfernen
        Call Shell_NotifyIcon(NIM_DELETE, TIcon)
        
    Else
    
        Cancel = 1
        
    End If
    
End Sub

Private Sub mnBeep_Click()

    Beep
    
End Sub

Private Sub mnExit_Click()

    ' Icon aus dem Systemtray entfernen
    Call Shell_NotifyIcon(NIM_DELETE, TIcon)
    
    Me.Refresh
    Unload Me
    
End Sub

Private Sub mnMsgShow_Click()

    MsgBox "Hier bin ich"
    
End Sub

Private Sub mnuChange_Click()

    ' neues icon zuweisen
    TIcon.hIcon = Picture1.DragIcon
    
    ' neuer ToolTiptext zuweisen
    TIcon.szTip = "Neuer ToolTipText" + Chr$(0)
    
    ' Änderungen durchführen
    Call Shell_NotifyIcon(NIM_MODIFY, TIcon)
    
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, x As _
    Single, Y As Single)
    
    Dim Msg As Long
    
    Msg = x / Screen.TwipsPerPixelX
    
    Select Case Msg
    
    ' Beep
    Case WM_MOUSEMOVE:
    Case WM_LBUTTONDBLCLK: Me.Show
    Case WM_LBUTTONDOWN:
    Case WM_LBUTTONUP:
    Case WM_RBUTTONDBLCLK: Me.Show
    Case WM_RBUTTONDOWN:
    Case WM_RBUTTONUP
    
        ' Diese Funktion muss vor dem anzeigen des
        ' Menüs ausgeführt werden.
        ' weitere Informationen stehen im KB Artikel Q135788 auf
        ' http://support.microsoft.com/kb/q135788/
        Call SetForegroundWindow(Me.hwnd)
        
        ' Menü anzeigen
        Me.PopupMenu mnBar
        
        ' bei Verwendung von "TrackPopupMenu" muss noch
        ' die Funktion "PostMessage Me.hwnd, WM_USER, 0&, 0&"
        ' ausgeführt werden
        
    End Select
    
End Sub

'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 48 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von TiKu am 25.01.2010 um 22:19

TIcon.ucallbackMessage = WM_MOUSEMOVE

Das ist übrigens extrem schlechter Stil.

Kommentar von Florian Rittmeier am 03.07.2009 um 09:29

Hallo Ben,

die entsprechende Funktionalität für .NET-Sprachen findest Du unter http://www.activevb.de/tipps/vbnettipps/tipp0030.html

Gruß,
Florian

Kommentar von Ben am 03.07.2009 um 02:17

Kann jmd. den Quelltext auch für VB Express Edition 2008 für Vista umschreibn? Ich kanns nicht, Anfänger, aba mich würde es intressieren, es erscheint oft die Fehlermeldung nicht declariert etc., als ich es in mein uelltext eingefügt habe.

Kommentar von Florian Rittmeier am 31.01.2008 um 13:48

Hallo Liesenberg,
das mit dem Text eintragen geht nicht direkt. Du kannst halt nur einen Text in eine Grafik umwandeln bzw. auf einer Picturebox passend ausgeben und dann diese Grafik unter anzeigen lassen. Falls Du nicht weißt, wie Du das hinbekommst, solltest Du direkt im VB5/6-Forum nachfragen und nicht hier.

Gruß Florian

Kommentar von Liesenberg am 31.01.2008 um 06:56

Hi,
kann ich alternativ auch Text im Systemtray anzeigen lassen??

Danke!

Kommentar von Florian Rittmeier am 04.01.2008 um 18:36

Hallo R.S.,
die Labels und Image-Steuerelemente sind vollkommen ohne Bedeutung. In der hoffentlich bald veröffentlichten Aktualisierung zu diesem Tipp, ist das nicht mehr drinne.

http://www.activevb.de/cgi-bin/tippupload/preview.pl?id=26

Gruß Florian

Kommentar von R.S. am 04.01.2008 um 09:01

Kann jemand erklären, wofür die ganzen Labels und vielen Pictureboxen sind?

Kommentar von Florian Rittmeier am 24.09.2007 um 23:09

Hallo Tobi,

Du musst im Form_QueryUnload die Variable Cancel auf den Wert 1 setzen, sofern UnloadMode gleich vbFormControlMenu ist.

Gruß Florian
PS: Solche Fragen besser im Hauptforum stellen.

Kommentar von Tobi am 24.09.2007 um 22:32

Hallo Zusammen,

der Tipp ist echt gold wert ;-)

Ich habe nur ein kleines Problem, welches sicher nur aus meinem Halbwissen herrührt...

Ich habe eine Appliktion mit mehreren Fenstern. Eines der Fenster wird immer angezeigt. Mehere andere werden normalerweise nicht benötigt. Sie können aber bei Bedarf aus einem Icon in der Taskbar aufgerufen werden.

Dazu hab ich mir das Form aus der Applikation etwas umgebaut. Clickt man auf einen Menu (Trybar Eintrag) wird das entsprechende Fenster mit "Form.Visible = True" angezeigt. Klappt auch ganz toll!

Nur wie kann ich nun verhindern, das die Fenster beim clicken auf das X ("Form_QueryUnload") ganz geschlossen werden. In einem der Forms ist ein TCP/IP Server implementiert, der eine Fernsteuerung des Programms ermöglicht. Treten bei der Kommunikation Fehler auf, werden in diesem Fenster die Fehlermeldungen angezeigt.

Lasse ich zu, das nach dem öffnen des Fensters via Traybar, und clicken auf das X dieser Teil der Applikation geschlossen/aus dem RAM gelöscht wird, ist die Komunikation via TCP/IP auch nicht mehr möglich. Das darf und soll nicht sein! Sprich es soll beim clicken auf das X ledigliglich ein "Form.Hide" ausgeführt werden.

Danke an alle die mir Helfen wollen/können...

Gruß
Tobi

Kommentar von Timon am 29.05.2007 um 13:28

| Wie kann ich, wenn mehrere Menüpunkte bestehen, einen
| bestimmten in FETT anzeigen lassen?

z.B. mnExit wird FETT angezeigt:
Case WM_RBUTTONUP: Me.PopupMenu mnBar, , , , mnExit

| Baut man den Tip in ein Programm ein, welches als Dienst
| bereits vor dem Login gestartet wird erscheint der Eintrag
| in der Systemtray nicht!

Nach MSDN muss die Form angezeigt werden, bevor man Shell_NotifyIcon aufruft.
(http://support.microsoft.com/?kbid=176085)
also:
Private Sub Form_Load()
'the form must be fully visible before calling Shell_NotifyIcon
Me.Show
Me.Refresh
...

| Kann man den Minimier-Button irgendwie abfangen..?

Ja, und zwar ganz einfach:
(auch wieder http://support.microsoft.com/?kbid=176085)

Private Sub Form_Resize()
If Me.WindowState = vbMinimized Then
Me.Hide
...
End If
End Sub


alles klar? :-)

Kommentar von Wolfgang am 10.10.2006 um 12:51

Baut man den Tip in ein Programm ein, welches als Dienst bereits vor dem Login gestartet wird erscheint der Eintrag
in der Systemtray nicht! Das ganze funktioniert nur wenn man den Dienst im eingeloggten System startet. Kann jemand helfen? Die Frage stand schon mal am 28.11.2000.

Kommentar von Philipp HERRMANN am 28.08.2006 um 16:40

Hallo,

der Tipp funzt tadellos!

Habe aber eine Frage:
Wie kann ich, wenn mehrere Menüpunkte bestehen, einen bestimmten in FETT anzeigen lassen?
Wenn ich also mit der RECHTEN Maustaste auf das Icon im Systray klicke, geht das Menü mit z. Bsp. 3 Menü-Punkten auf. Alle 3 sind in der gleichen Schrift. Wie schaffe ich es, dass einer davon (nämlich der, der beim Drücken der LINKEN Maustaste eine Reaktion auslöst) FETT geschrieben wird?

Philipp

Kommentar von Florian Rittmeier am 09.09.2005 um 11:41

@Kriechi

Indem Du das Menü im Menüeditor bearbeitest.

Gruß Florian

Kommentar von Kriechi am 09.09.2005 um 10:07

Hallo1
super tipp, nur wie kann ich das popup menü bearbeiten, eintrege löschen/ hinzufügen?

mfg

Kommentar von Florian Rittmeier am 01.06.2004 um 19:30

Hallo Matthias,

stell die Frage besser im Forum.

Gruß Florian

Kommentar von Matthias am 01.06.2004 um 11:54

Hallo!
Kleine Frage: Wenn das Popup-Menü in der Taskbar geöffnet ist, man aber keinen Eintrag anklicken möchte - wie kann ich das Menü wieder ausblenden lassen wenn die linke Maustaste geklickt wird (wie bei allen anderen Symbolen)?

Grüße Matthias

Kommentar von Florian Rittmeier am 19.04.2004 um 15:26

Hallo WellingaDaDon,

das Abfangen dieser Aktion ist leider nicht so einfach. http://support.microsoft.com/default.aspx?scid=kb;de;D34489 zeigt jedoch wie es geht.

Gruß Florian

Kommentar von WellingaDaDon am 18.04.2004 um 09:31

Kann man den Minimier-Button irgendwie abfangen, sodass das Programm dann im Systemtray minimiert wird und nicht nur normal minimiert wird?

WellingaDaDon

Kommentar von Lukas am 03.04.2004 um 23:38

Man muss einfach zum aktualisieren den Befehl

Shell_NotifyIcon NIM_MODIFY, TIcon

einsetzen dann werden die neuen Werte übernommen...
Gruß Lukas

Von Sebastian am 27.11.2003 um 13:41
Wie kann ich die Eigenschaft TIcon.szTip zur Laufzeit ändern??

Danke

Kommentar von Florian Rittmeier am 18.12.2003 um 20:01

Hallo casper,

dazu musst Du im Resize-Ereignis der Form überprüfen, welchen Wert die WindowState-Eigenschaft des Formulars hat. Wenn er vbMinimized ist, dann musst Du, sofern der Status vorher anders war, das Icon zum Systemtray hinzufügen.
Ansonsten halt entfernen.

Wenn Du noch fragen hast, poste doch einfach am Hauptforum, das ist unkomplizierter.

Gruß Florian

Kommentar von cdfmi am 18.12.2003 um 08:06

Hallo,

das mit dem icon klappt ja ganz gut, nur hab ich folgendes problem. Das icon soll nur dann angezeigt werden, wenn die Form minimiert wurde... ist es maximiert oder normal, soll es wie jedes andere Program in der unteren leiste angezeigt werden.

nur wie?

danke
casper

Kommentar von Sebastian am 27.11.2003 um 13:41

Wie kann ich die Eigenschaft TIcon.szTip zur Laufzeit ändern??

Danke

Kommentar von Franz Grillmeier am 26.11.2003 um 09:33

Funktioniert einwandfrei, nur: wenn man den Mauszeiger
über das Symbol bewegt, entsteht ein eigenartiges Kratzen
im Lautsprecher (na ja, wer's mag...).
Abhilfe:
in der Sub "Picture1_MouseMove(..)" die Zeile

Case WM_MOUSEMOVE: Beep

löschen.

Kommentar von MorchManN am 13.11.2003 um 13:54

Hey das is echt cool!
Ich hab diesen Code in mein Programm integriert,
aber was hat es mit den Images auf sich?
Ich habe in mein Programm den Form_Load die Menü_Clicks und Constanten eingefügt. Nur halt das mit den Images weiß ich net was die machen!
Bitte um Hilfe!
Thx...

Kommentar von Oliver Hausler am 10.10.2003 um 22:56

Es gibt zwei Stellen, an denen der Tipp noch verbesserungswürdig ist. Ich habe den Code eingestellt:

Private Sub mnExit_Click(Index As Integer)
Shell_NotifyIcon NIM_DELETE, TIcon
Me.Refresh 'Hier muss noch ein Refresh rein, weil sonst nach dem Beenden das Icon hängenbleibt, bis man es mit der Maus berührt
Unload Me
End Sub


Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, _
x As Single, Y As Single)
Dim Msg&
Msg = x / Screen.TwipsPerPixelX

Select Case Msg
Case WM_MOUSEMOVE: 'hier muss der Beep raus, da dies bei gleichzeitig offenen Forms unter Umständen zu wildem gepiepse führt
Case WM_LBUTTONDBLCLK: Me.Show
Case WM_LBUTTONDOWN:
Case WM_LBUTTONUP:
Case WM_RBUTTONDBLCLK: Me.Show
Case WM_RBUTTONDOWN:
Case WM_RBUTTONUP: Me.PopupMenu mnBar
End Select
End Sub

Kommentar von Florian Rittmeier am 31.08.2003 um 14:28

Hallo Leute,

all jene von Euch die ein Problem hatten
welches sich über die Meldung "Shell_notifyIcon Fail" bemerkbar macht, lesen bitte
http://www.computing.net/windows2000/wwwboard/forum/23795.html

Gruß Florian

Kommentar von Lucky11 am 27.06.2003 um 18:19

Ich habe von den Beispielen "Dienst und Programmsymbol in der Taskbar" einen Dienst erstellt mein Problem ist, beim Neustarten des Rechnerst oder Abmelden startet der Dienst aber das Icon erscheint nicht? Was mache ich falsch?

Kommentar von Matthias am 03.01.2003 um 19:09

Zu Tipp "0095": Halla,
Ich bin noch kein sehr erfahrener VB Programmierer, desshalb würde ich mich freuen wenn mir jemand das Beispiel genauer erklären kann, da es bei mir so nicht funktioniert. Danke im vorraus! Matthias

Kommentar von OLLI am 19.12.2002 um 18:47

Wenn ich das Projekt starte, erscheint das icon in der taskleiste. wenn ich mit der maus drüber fahre, oder anklicke, spielt mein pc-lautsprecher total verrückt. an was liegt das?

Kommentar von Top am 30.11.2002 um 23:45

Hi!
- 'mnbar' ist ein Menü! Es lässt sich im Menü-Editor (Strg-E) bearbeiten.
- Das Icon austauschen geht mit Shell_NotifyIcon NIM_MODIFY, TIcon
Gruß
Top

Kommentar von Inferno am 10.11.2002 um 02:10

Hallo und guten Tag,
ich sende ihnen diese Mail, da ich gerne wissen würde, wie man Sachen aus der Taskbar (ganz unten und ganz rechts) entfernt. Das heißt ohne sie zu löschen (bzw. das Programm). Es sollen nur die Symbole verschwinden. Wenn man mit einem Rechtsklick auf die Taskleiste klickt, so kann man zwar andere Dinge erstellen/verändern/aufrufen, aber nicht die Haupttaskleiste verändern.
Ich bitte um Antwort. Danke (ich habe windows me)

Kommentar von am 10.10.2002 um 01:06

Kommentar von Dirk am 21.08.2002 um 14:54

Wie kann ich ToolTipTextes immer wieder auffrischen??
z.B.: Timerablauf anzeigen wenn ich mit der Maus auf dem Icon stehe.Kann mir da vielleicht jemand helfen????

Kommentar von MisterMi am 06.08.2002 um 19:44

Ich teste unter Windows 2000 mit VB6.0. Habe obiges Beispiel und ein weiteres von Euch ("mane") ausprobiert - in meiner Taskleiste tut sich überhaupt nichts. Gibt es einen bestimmten Zeitpunkt des Aufrufs oder muß man etwas besonderes beachten?
Vielen Dank für Eure tollen Hilfen. Macht echt Spaß. Danke!
Gruß
MisterMi

Kommentar von krage am 27.07.2002 um 15:13

Im Programmcode steht ein Steuerelement mit Namen "mnbar". Kann mir jemand erklären was das ist? Hat wohl mit dem Rechtsklick-Menü zu tun. Wo finde ich dieses Steuerelement?
Freundliche Grüße
Gerold

Kommentar von Jana am 14.07.2002 um 19:39

Ich bekomme beim Start von Windows XP seit kurzem die Meldung "Shell_notifyIcon Fail". Wie kann ich dafür sorgen, dass diese Meldung nicht mehr angezeigt wird?
Dank und Gruß

Kommentar von Marcus am 12.07.2002 um 15:23

Hi,
möchte gerne wenn man auf einen Menüpunkt klickt, das Icon ausgetauscht wird. Wie kann ich das machen?
gruss
marcus

Kommentar von BenniVB am 09.06.2002 um 19:10

Hallo,
Ist es möglich, wenn man diesen Code entsprechend erweitert und aktualisiert, die modernen Balloon-Tips aus Windows XP für seine eigene Anwendung zu gewinnen?
Gruß,
BenniVB

Kommentar von Mroz Markus am 23.03.2002 um 11:17

Ich möchte ein Symbol von der Taskleiste loswerden.Wie entferne ich ein Symbol aus der Taskleiste unten rechts?Markus

Kommentar von W.F. Gerbode am 21.01.2002 um 18:28

Ich bekomme beim Start von Windows XP seit kurzem die Meldung "Shell_notifyIcon Fail". Wie kann ich dafür sorgen, dass diese Meldung nicht mehr angezeigt wird?
Dank und Gruß
wfg

Kommentar von Stefan am 18.08.2001 um 22:15

Kann ich da auch meinen eigenen Text 'reinbringen, in die Traybar? Ich habe vor,
ähnlich "FreeMem Pro" einen Wert in der Traybar unterzubringen. Kann man das irgendwie erreichen?
Danke!!
Stefan

Kommentar von Martin Straube am 05.08.2001 um 14:21

Hallo Stephan
Setz die Form ( dazu muss dann das Handle der Form aber übergeben wurden sein ) mit SetWindowForeground in den Fordergrund ( auch wenn Sie versteckt ist )... danach müsste eigentlich das Kontextmenü des Systrayicons verschwinden wenn du irgend wo anders ( z.B. Desktop ) nen Kontextmenü öffnest.
Mfg
Martin Straube

Kommentar von Stephan am 07.06.2001 um 15:34

Hi,
Das funktioniert soweit ganz gut, jedoch gibt es ein Problem mit dem LostFocus. Wenn das Icon im Tray angezeigt wird und ich das Menue öffne, aber keinen Eintrag auswähle, bleibt das Menue solange sichtbar, bis ich es erneut mit Mausklicks versorge. Gibt es eine Möglichkeit, daß das Menue mitbekommt, das der Focus an ein anderes Fenster etc. weiter gegeben wurde? Ist dieses Problem vielleicht nur unter NT 4.0? Danke für jeden Tip, Gruß
Stephan

Kommentar von Michael G. am 22.05.2001 um 14:28

D:\AAA VB\Tips & Tricks für die Homepage\Tip 095\Tray Icon erstellen\Form1.frm
*grins*

Kommentar von vbipa am 12.05.2001 um 18:23

hallo,
nun das funktioniert schon aber wenn ich mein Programm starte geht es gleich unten in die Taskleiste dieses soll es aber nicht es sollte erst erscheinen und bei betätigen des schließens erst dort hinein wie bei Napster!!
gibt es da eine Lösung?
vbipa

Kommentar von SKIRON am 29.04.2001 um 16:44

Zum Tip oben :
Der Tip ist ok, allerdings ist in der Projektdatei ein falscher Eintrag, so daß beim laden des Projektes eine Fehlermeldung erscheint.
Fehlerbehebung :
Öffne Projektdatei mit Notepad und entferne hinter "Form=" den Hyperlink-Verweis, so daß nur noch "Form1" dort steht.
biba...SKIRON

Kommentar von Markus am 28.11.2000 um 20:01

Frage: Wie kann man erreichen, daß nach Abmelden und erneutem Anmelden eines Users (NT) das Programmsymbol weiterhin oder wieder erscheint? (es handelt sich hierbei um eine Serveranwendung (Dienst), die auch dann läuft, wenn keiner angemeldet ist.)

Kommentar von Ben am 20.11.2000 um 14:36

Hallo,
ich möchte für ein Programm ein Symbol je nach Status (aktiv, inaktiv...) in der Taskbar haben. Dafür stelle ich mir vor, dass ich zwei oder drei verschiedene Images habe und diese je nach Staus unten sichtbar mache. Der Tip ist mir leider etwas zu kompliziert. Kann mir da jemand weiterhelfen?
Ben