Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0079: ListBox per API auslesen

VB 5/6-Tipp 0079: ListBox per API auslesen

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: SendMessageA (SendMessage)

Download: Download des Beispielprojektes [3,23 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Porject1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Textfeld "Text1"
' Steuerelement: Listen-Steuerelement "List1"
' Steuerelement: Listen-Steuerelement "List2"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Beschriftungsfeld "Label1"

Option Explicit

Private Declare Function SendMessage Lib "user32" Alias _
        "SendMessageA" (ByVal hWnd As Long, ByVal wMsg _
        As Long, ByVal wParam As Long, lParam As Any) _
        As Long

Const LB_GETCOUNT = &H18B
Const LB_GETTEXT = &H189
Const LB_GETTEXTLEN = &H18A
Const LB_GETCURSEL = &H188

Private Sub Form_Load()
  List1.AddItem "Bohnen"
  List1.AddItem "Erbsen"
  List1.AddItem "Möhren"
  List1.AddItem "Mais"
  List1.AddItem "Kartoffeln"
  List1.AddItem "Gurken"
  List1.AddItem "Tomaten"
End Sub

Private Sub Command1_Click()
  Dim lCnt&, X&, L&, Buffer$, Item$, LBidx&
     
    List2.Clear
    lCnt = SendMessage(List1.hWnd, LB_GETCOUNT, 0, 0)
    
    If lCnt > 0 Then
      For X = 0 To lCnt - 1
        List2.AddItem GetListBoxEntry(List1.hWnd, X)
      Next X
    End If
    
    LBidx = SendMessage(List1.hWnd, LB_GETCURSEL, 0, 0)
    If LBidx <> -1 Then
      Text1.Text = GetListBoxEntry(List1.hWnd, LBidx)
    Else
      Text1.Text = ""
    End If
End Sub

Private Function GetListBoxEntry(hWnd&, LbItem&) As String
  Dim L&, Buffer$
  
    L = SendMessage(hWnd, LB_GETTEXTLEN, LbItem, 0)
    Buffer = Space$(L + 1)
    L = SendMessage(hWnd, LB_GETTEXT, LbItem, ByVal Buffer)
    GetListBoxEntry = Left$(Buffer, L)
End Function
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Porject1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 3 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.