VB 5/6-Tipp 0073: Splitterbar, frei verschiebbarer Trennbalken zweier Objeke

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Textfeld "Picture2"
' Steuerelement: Textfeld "Picture1"
Option Explicit


Const Trennbalken = 120
Private Prozent As Single, Drag_Flag As Boolean

Private Sub Form_Load()
  Prozent = 0.5
End Sub

Private Sub Form_Resize()
  Textboxen_Zeichnen
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, _
                           X As Single, Y As Single)
  Drag_Flag = True
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, _
                           X As Single, Y As Single)
  If Drag_Flag Then
    Prozent = Y / ScaleHeight
    If Prozent < 0.065 Then Prozent = 0.065
    If Prozent > 0.94 Then Prozent = 0.94
    Textboxen_Zeichnen
  End If
End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, _
                         X As Single, Y As Single)
  Drag_Flag = False
End Sub

Private Sub Textboxen_Zeichnen()
  Dim HöheText1&
  Dim HöheText2&

    HöheText1 = (Me.ScaleHeight - Trennbalken) * Prozent
    Picture1.Move 0, 0, ScaleWidth, HöheText1

    HöheText2 = (ScaleHeight - Trennbalken) - HöheText1
    Picture2.Move 0, HöheText1 + Trennbalken, ScaleWidth, HöheText2
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------