Wie kann ich eine Datei oder ein Verzeichnis umbenennen oder verschieben?

Die hier gezeigten Quelltexte stammen von  Helge Rex.

Inhalt

	VB-Funktionen
	API-Funktionen
	WSH-Funktionen

Visual Basic stellt die Methode Name() zur Verfügung:

Private Sub TestSub()
    Dim strOldFile As String
    Dim strNewFile As String

    strOldFile = Environ$("WINDIR") & "\setuplog.txt"
    strNewFile = Environ$("WINDIR") & "\newsetuplog.txt"

    Name strOldFile As strNewFile
End Sub

Listing 1: Datei oder Verzeichnis mit VB umbenennen oder verschieben

Visual Basic selbst leitet die Parameter der Methode Name() an die API-Funktion MoveFile weiter:

Private Declare Function MoveFile Lib "kernel32.dll" _
                Alias "MoveFileA" ( _
                ByVal lpExistingFileName As String, _
                ByVal lpNewFileName As String) As Long

Private Sub TestSub()
    Dim strOldFile As String
    Dim strNewFile As String

    strOldFile = Environ$("WINDIR") & "\setuplog.txt"
    strNewFile = Environ$("WINDIR") & "\newsetuplog.txt"

    MoveFile strOldFile, strNewFile
End Sub

Listing 2: Datei oder Verzeichnis mit API umbenennen oder verschieben

MoveFile ist nicht in der Lage, Dateien über Partitionsgrenzen hinweg zu verschieben. Wer diese Funktionalität benötigt, der muß sich mit der API-Funktion MoveFileEx beschäftigen. Diese API-Funktion bietet darüber hinaus auch die Möglichkeit, die Datei beim nächsten Systemstart zu kopieren. Das ist natürlich für eigene Setup-Tools ein idealer Ansatz.

Das FSO stellt die Methode MoveFile() zur Verfügung.

Private Sub TestSub()
    Dim objFSO As Object
    Dim strOldFile As String
    Dim strNewFile As String

    strOldFile = Environ$("WINDIR") & "\setuplog.txt"
    strNewFile = Environ$("WINDIR") & "\newsetuplog.txt"

    Set objFSO = CreateObject("Scripting.FileSystemObject")
    objFSO.MoveFile strOldFile, strNewFile
    Set objFSO = Nothing
End Sub

Listing 3: Datei oder Verzeichnis mit FSO umbenennen oder verschieben